Kako paketno poslati vse datoteke v mapi Windows prek ločenih Outlookovih e-poštnih sporočil

Če želite nekomu poslati vse datoteke v mapi Windows prek posameznih Outlookovih e-poštnih sporočil, lahko uporabite metodo, predstavljeno v tem članku. Uporablja kodo VBA, ki je zelo učinkovita.

Po branju prejšnjega članka – “3 hitre metode za pripenjanje vseh datotek v lokalni mapi Outlookovemu e-poštnemu sporočilu«, nekateri uporabniki želijo poslati vse datoteke v lokalni mapi prek ločenih e-poštnih sporočil. Na standarden način bi morali ustvariti e-poštna sporočila in priložiti datoteke eno za drugo. Je precej težavno. Zato vam bomo v nadaljevanju predstavili učinkovitejši način.

Paketno pošiljanje vseh datotek v mapi Windows prek ločenih e-poštnih sporočil

1. Najprej zaženite program Outlook.
2. Nato v Outlooku odprite urejevalnik VBA glede na članek – "Kako zagnati kodo VBA v Outlooku".
3. Nato kopirajte in prilepite naslednjo kodo VBA v projekt ali modul.

Sub SendAllFilesInSeparateEmails()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim objFile As Object
    Dim strWindowsFolder As String
    Dim objFileSystem As Object
    Dim objMail As Outlook.MailItem
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
       Set objWindowsFolder = objFileSystem.GetFolder(strWindowsFolder)
 
       'Send each file in an email
       For Each objFile In objWindowsFolder.Files
 
           'Create a new mail
           Set objMail = Outlook.Application.CreateItem(olMailItem)
           'Change the details as per your needs
           With objMail
                .Subject = Left(objFile.Name, Len(objFile.Name) - (Len(objFileSystem.GetExtensionName(objFile.Name)) + 1))
                .Attachments.Add objFile.Path
                .Recipients.Add ("someone@datanumen.com")
                .Recipients.ResolveAll
                .Send
          End With
       Next
 
       'Prompt you when completing sending
       MsgBox "All done!", vbOKOnly + vbExclamation
    End If
End Sub

4. Po tem lahko ta makro zaženete naenkrat. Samo pritisnite tipko "F5".
5. Nato bi morali v pojavnem pogovornem oknu izbrati izvorno mapo Windows.
6. Končno bo Outlook priložil vse datoteke v tej mapi Windows, da bo ločil e-poštna sporočila in jih poslal vnaprej določenemu prejemniku.
7. Ko se konča, boste prejeli sporočilo z pozivom »Vse končano!«.

Bodite pozorni na Outlook Health

Čeprav Outlook velja za najbolj priljubljenega e-poštnega odjemalca na trgu, ima še vedno usodno napako. To je njegova ranljivost. Z drugimi besedami, Outlook je nagnjen k različnim napakam in poškodbam. Zato morate biti zelo pozorni na zdravje svojega Outlooka in ga zaščititi pred poškodbami. Poleg tega morate redno varnostno kopirati svoje Outlookove datoteke. Poleg tega je priporočljivo, da si priskrbite orodje za popravilo PST, kot je DataNumen Outlook Repair. Lahko popravilo Outlook težave brez težav.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z sql popravek in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com