2 hitra načina za pridobivanje odsekov iz dokumenta Word

V tem članku vam bomo ponudili dva hitra in enostavna načina za pridobivanje odsekov iz Wordovega dokumenta v drugega ali več.

Pogosto se zgodi, da se vsebina izvleče iz enega dokumenta v drugega. V prejšnjem članku smo razpravljali o tem, kako iz dokumenta izvleči strani. Za podrobne informacije si lahko ogledate ta članek: 2 hitra načina za pridobivanje posameznih strani iz dokumenta Word

Danes vam bomo pokazali, kako izvleči po odsekih.    

1. način: Izvleček trenutnega odseka v nov dokument

1. Najprej postavite kazalec v ciljni odsek.
2. Nato pritisnite “Alt + F11”, da v programu Word prikličete urejevalnik VBA.
3. Nato v levem stolpcu kliknite “Normal”.
4. V menijski vrstici kliknite »Vstavi«.
5. Nato v spustnem meniju izberite “Module”.
6. Dvokliknite, da odprete novi modul, in prilepite naslednje kode:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Nato v menijski vrstici kliknite »Zaženi« ali pritisnite »F5«.
8. Nato se prikaže okno »Brskaj«. Izberite mesto za shranjevanje novega dokumenta in kliknite »V redu«.
9. In v polje »Ime datoteke« vnesite ime nove datoteke in kliknite »V redu«.

Zdaj ste razdelek izvlekli v nov dokument.

2. metoda: Izvlecite vsak odsek v dokumentu na posamezne nove

Tako vam lahko pomaga pri paketni obdelavi vseh odsekov v dokumentu. Seveda bomo potrebovali tudi makro.

1. Za začetek odprite ciljni dokument.
2. Nato sledite korakom v metodi 1 za namestitev in zagon makra.
3. Le ta čas makro zamenjajte s tem:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. Kljub temu v oknu »Brskaj« izberite pot do pomnilnika in kliknite »V redu«.

Odpravite dražilne napake besed

Med njegovo uporabo je običajno naleteti na napake v programu Word. Moteče je, da si moramo vzeti čas obnoviti besedo čimprej. Ker dlje kot ga odlašamo, hujša je lahko izguba podatkov. Zato je priporočljivo, da se vnaprej lotite pripomočka za popravilo.

Uvod avtorja:

Vera Chen je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z poškodovan xls in pdf popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com