2 rýchle spôsoby vyhľadania alebo odstránenia viet obsahujúcich konkrétny text vo vašom slove

V tomto článku vám ponúkneme 2 rýchle spôsoby, ako vyhľadať alebo odstrániť vety obsahujúce konkrétny text vo vašom slove.

Je všetkým známe, že pomocou funkcie „Nájsť a nahradiť“ vo Worde môžeme jednoducho nájsť všetky výskyty konkrétnych slov. Potom nebudeme mať problém s ich zvýraznením, nahradením alebo odstránením. Ako vidíte, cieľom je slovo alebo fráza. Dnes vám však s radosťou prezradíme makro spôsob, ako nájsť alebo odstrániť vety obsahujúce určitý text.

Metóda 1: Vyhľadanie alebo odstránenie viet obsahujúcich konkrétny text

1. Na začiatok stlačte kombináciu klávesov „Alt + F11“, čím spustíte editor VBA v programe Word.
2. Ďalej vytvorte nový modul kliknutím na „Normálny“.
3. Potom kliknite na „Vložiť“ a zvoľte „Modul“, aby ste získali nový.
4. A modul otvorte dvojitým kliknutím.
5. Teraz vložte nasledujúce kódy:

Sub DeleteSentencesContainingSpecificWords()
  Dim strTexts As String
  Dim strButtonValue As String
 
  strTexts = InputBox("Enter texts to be found here: ")
 
  With Selection
    .HomeKey Unit:=wdStory
 
    '  Find the entered texts.
    With Selection.Find
      .ClearFormatting
      .Text = strTexts
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
 
    Do While .Find.Found = True
      '  Expand the selection to the entire sentence.
      Selection.Expand Unit:=wdSentence
      strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
      If strButtonValue = vbYes Then
        Selection.Delete
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End Sub

6. Ďalej kliknite na „Spustiť“.
7. K dispozícii bude vstupné pole so žiadosťou o zadanie textu. Stačí napísať spoločný text, ktorý obsahujú všetky vety. Kliknite na „OK“.
8. Potom uvidíte vetu obsahujúcu vybraný text s výzvou na odoslanie správy. Kliknutím na „Áno“ vetu odstránite a kliknutím na „Nie“ ju ponecháte.
9. Po potvrdení sa vyberie ďalšia veta s určeným textom. A nachádza sa tu aj potvrdzovacie pole. Makro vás prevedie celým dokumentom, nájde cieľové vety a zakaždým si vyžiada potvrdenie.

Metóda 2: Vyhľadanie alebo odstránenie viet obsahujúcich akýkoľvek text v zozname

Pomocou makra v metóde 1 môžete vyhľadávať iba jedno slovo alebo frázu naraz. Makro môžete určite spustiť opakovane a vyhľadať tak, aby ste našli viac výskytov slov alebo fráz. Aby sme vyhoveli potrebe viacnásobného vyhľadávania, poskytneme vám ďalšie makro.

1. Najprv vložte všetky cieľové texty do nového dokumentu. Uistite sa, že každý text zaberá jeden odsek bez medzery. Zatvorte a uložte dokument.
2. Ďalej nainštalujte a spustite makro s presnými krokmi v metóde 1.
3. Potom nahraďte makro týmto:

Sub DeleteSentencesContainingSpecificWordsOnAList()
  Dim objListDoc As Document, objTargetDoc As Document
  Dim objParaRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String, strButtonValue As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    If .Show = -1 Then
      strFileName = .SelectedItems(1)
    Else
      MsgBox "No file is selected! Please select the target file."
      Exit Sub
    End If
  End With
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
    With Selection
      .HomeKey Unit:=wdStory
 
      '  Find target words.
      With Selection.Find
        .ClearFormatting
        .Text = objParaRange
        .MatchWholeWord = True
        .MatchCase = False
        .Execute
      End With
 
      '  Expand the selection to the entire sentence.
      Do While .Find.Found
        Selection.Expand Unit:=wdSentence
        strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
        If strButtonValue = vbYes Then
          Selection.Delete
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
  Next objParagraph
End Sub

4. Teraz sa otvorí okno „Prechádzať“. Vyberte dokument, ktorý ste práve uložili, a kliknite na tlačidlo „Otvoriť“.
5. Nasledujúci postup je rovnaký ako v metóde 1.

Prístup k práci s poškodenými dokumentmi

Strata cenných údajov je absolútne zničujúca. Môže to dokonca nechať vaše podnikanie v stávke. Aby ste sa vyhli takejto frustrácii, musíte sa zmocniť a Oprava slova nástroj čo najskôr. Takýto nástroj vám pomôže zvíťaziť v boji s poškodením dokumentov.

Úvod autora:

Vera Chen je expertka na obnovu dát v DataNumen, Inc., ktorá je svetovým lídrom v oblasti technológií obnovy dát, vrátane opraviť Excel a pdf oprava softvérových produktov. Pre viac informácií navštívte www.datanumen. S