Ako rýchlo exportovať všetky obrázkové prílohy e-mailu programu Outlook do pracovného hárka programu Excel

Ak chcete rýchlo exportovať všetky obrázkové prílohy e-mailu programu Outlook do pracovného hárka programu Excel, môžete si prečítať tento článok. Tu vám ukážeme efektívnejší spôsob ako ručný export.

Keď dostanete e-mail s množstvom obrázkových príloh a chcete ich použiť na vytvorenie zostavy v Exceli, musíte hľadať spôsob, ako tieto obrázky hromadne exportovať do excelovského hárka. V nasledujúcom texte vám predstavíme takýto prístup.

Exportujte všetky obrázkové prílohy e-mailu do pracovného hárka programu Excel

1. Na začiatok prejdite do aplikácie Outlook normálnym spôsobom.
2. Potom v okne programu Outlook stlačte klávesové skratky „Alt + F11“, čím sa zobrazí okno „Microsoft Visual Basic for Applications“.
3. Na tejto obrazovke musíte otvoriť modul, ktorý sa nepoužíva, alebo rovno vložiť nový.
4. Ďalej by ste mali skopírovať časť kódu VBA nižšie do tohto modulu.

Sub ExportAllImageAttachmentsToExcelWorksheet()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim strImage As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim objFile As Object
    Dim objFiles As Object
    Dim nRow As Integer
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
 
       'Save the image attachments to a temporary folder
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       'Create a new Excel workbook
        Set objExcelApp = CreateObject("Excel.Application")
        Set objExcelWorkbook = objExcelApp.Workbooks.Add
        Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
        objExcelApp.Visible = True
        objExcelWorkbook.Activate
 
        'Get the images in the temporary folder
        Set objFiles = objFileSystem.GetFolder(strTempFolder).Files
 
        'Insert the images into this new Excel worksheet
        For Each objFile In objFiles
            strImage = strTempFolder & Trim(objFile.Name)
            nRow = nRow + 1
            With objExcelWorksheet
                 .Range("A" & nRow).value = objFile.Name
                 'Change the height and width as per your needs
                 .Range("B" & nRow).ColumnWidth = 10
                 .Range("B" & nRow).RowHeight = 80
                 .Range("B" & nRow).Activate
                 With .Pictures.insert(strImage)
                      With .ShapeRange
                           .LockAspectRatio = msoTrue
                           .Width = 50
                           .Height = 70
                      End With
                 End With
                 .Columns("A").AutoFit
                 .Activate
            End With
       Next
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. Potom môžete makro ukončiť.
6. Potom prejdite na „Súbor“ > „Možnosti“ > „Panel s nástrojmi Rýchly prístup“ a pridajte toto makro na panel s nástrojmi Rýchly prístup.
7. Nakoniec si toto makro môžete vyskúšať práve teraz.

• Najprv vyberte alebo otvorte zdrojový e-mail.
• Potom kliknite na tlačidlo makra na paneli s nástrojmi Rýchly prístup.
• Po dokončení makra získate pracovný hárok programu Excel, ktorý je zobrazený ako nasledujúca snímka obrazovky:

Chráňte súbor programu Outlook pred poškodením

Je známe, že Outlook je náchylný na korupciu. Preto by sme mali pochopiť, ako chrániť poškodenie formulárov programu Outlook. Po prvé, aby ste zablokovali útoky vírusov, je potrebné nainštalovať antivírusový softvér a nikdy nesťahovať neznámu prílohu. Okrem toho je lepšie, ak zoženieme účinný nástroj na opravu, ako napr DataNumen Outlook RepairMôže ponúknuť najúčinnejší liek v prípade Výhľadová korupcia.

Úvod autora:

Shirley Zhang je expertkou na obnovu dát v DataNumen, Inc., ktorá je svetovým lídrom v oblasti technológií obnovy dát, vrátane zotavenie sql a výhľadové softvérové ​​produkty na opravu. Pre viac informácií navštívte www.datanumen. S