Ako rýchlo pripojiť konkrétne snímky a PowerPoint Prezentácia na váš e-mail programu Outlook

Ak chcete extrahovať konkrétne snímky z a PowerPoint prezentáciu do samostatnej novej prezentácie a pripojiť ju k e-mailu Outlooku, môžete využiť spôsob zdieľaný v tomto článku.

Namiesto pripojenia celého PowerPoint prezentácia do e-mailu, ak chcete pripojiť konkrétne snímky prezentácie, je všeobecne potrebné najskôr skopírovať konkrétne snímky do novej prezentácie. Je to príliš problematické. Preto vám tu ukážeme metódu, ktorá to dokáže zrealizovať naraz.

Pripojte konkrétne snímky a PowerPoint Prezentácia na e-mail

1. Najskôr otvorte konkrétny údaj PowerPoint prezentáciu.
2. Potom v PowerPoint V okne aplikácie stlačte klávesy „Alt + F11“ a vstúpte do editora VBA.
3. Ďalej v novom okne vytvorte nový modul kliknutím na položky „Vložiť“> „Modul“.
4. Následne skopírujte a prilepte nasledujúci kód VBA do tohto modulu.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. Potom môžete zavrieť aktuálne okno.
6. Neskôr prejdite na „Súbor“> „Možnosti“> „Panel nástrojov Rýchly prístup“ a pridajte nové makro na Panel nástrojov Rýchly prístup.
7. Nakoniec môžete vyskúšať toto makro.

• Na začiatok vyberte konkrétne snímky, ktoré chcete extrahovať.
• Potom kliknite na tlačidlo makra na paneli s nástrojmi Rýchly prístup.
• Hneď sa zobrazí e-mail programu Outlook, v ktorom je PowerPoint prezentácia, ktorá je extrahovaná zo zdrojovej prezentácie.

Využite efektívny nástroj na obnovenie

Ako všetci vieme, program Outlook je vybavený vstavaným nástrojom na opravu - Scanpst. Môže sa však jednoducho vyrovnať s malými chybami v programe Outlook. Ak je to, s čím ste konfrontovaní, vážne poškodenie, nebude to mať žiadny vplyv. V tom okamihu vám nezostáva nič iné, ako sa obrátiť na iný výkonný a dôveryhodný nástroj na opravu, ako je DataNumen Outlook Repair. Vďaka tomu budete schopní zachrániť poškodený súbor programu Outlook.

Úvod autora:

Shirley Zhang je expertkou na obnovu dát v DataNumen, Inc., ktorá je svetovým lídrom v oblasti technológií obnovy dát, vrátane poškodený mdf a výhľadové softvérové ​​produkty na opravu. Pre viac informácií navštívte www.datanumen. S