Ako nastaviť iný predvolený čas pripomenutia pre rôzne druhy označených položiek v programe Outlook

V predvolenom nastavení bude Outlook automaticky používať predvolený čas pripomenutia úloh na všetky druhy označených položiek. Ak však chcete použiť iný čas pripomenutia označených položiek na základe typu položky, môžete sa obrátiť na metódu uvedenú v tomto článku.

Outlook umožňuje nastaviť predvolený čas pripomienky pre všetky označené položky bez ohľadu na typ položky. Môžete ísť do ponuky „Súbor“ a kliknúť na „Možnosti“. Potom v okne „Možnosti programu Outlook“ uvidíte možnosť „Predvolený čas pripomienky“ na karte „Úlohy“, ako je znázornené na nasledujúcej snímke obrazovky.

Väčšina používateľov však dúfa, že pre rôzne druhy označených položiek použije rôzne časy pripomenutia, napríklad „9:00“ pre označené e-maily a „17:30“ pre označené kontakty. V nasledujúcom texte sa zameriame na tento príklad, aby sme predstavili metódu.

Nastaviť iný predvolený čas pripomenutia pre rôzne druhy označených položiek

1. Ak chcete začať, spustite aplikáciu Outlook.
2. Potom otvorte editor Outlook VBA s odkazom na „Ako spustiť kód VBA v programe Outlook".
3. V nasledujúcom okne „Microsoft Visual Basic for Applications“ skopírujte nasledujúci kód do projektu „ThisOutlookSession“.

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Potom reštartujte Outlook, aby ste toto makro aktivovali.
5. Odteraz bude zakaždým, keď nahlásite e-mail, čas pripomenutia nastavený na „10:00“ v deň nahlásenia.
6. A keď nahlásite kontakt, čas pripomenutia sa nastaví na „17:30“ v deň nahlásenia.

Pružne riešte problémy s programom Outlook

V programe Outlook sa môžete stretnúť so všetkými druhmi problémov. Preto sa musíte vopred naučiť niekoľko opatrení na ich riešenie. Napríklad, ak sa váš Outlook často reštartuje, musíte opraviť Office alebo vypnúť doplnky tretích strán atď. Alebo ak je váš súbor PST programu Outlook napadnutý, môžete najprv vyskúšať nástroj na opravu doručenej pošty. Ak zlyhá, môžete sa naďalej uchýliť k výkonnému externému nástroju, ako je DataNumen Outlook Repair.

Úvod autora:

Shirley Zhang je expertkou na obnovu dát v DataNumen, Inc., ktorá je svetovým lídrom v oblasti technológií obnovy dát, vrátane zotavenie mdf a výhľadové softvérové ​​produkty na opravu. Pre viac informácií navštívte www.datanumen. S