Ako automaticky používať rôzne farby písma na odpovedanie a preposielanie e-mailov pomocou programu Outlook VBA

V predvolenom nastavení nemôžete nechať Outlook automaticky používať rôzne farby písma na odpovedanie a preposielanie e-mailov. Preto, ak máte takúto požiadavku, môžete si prečítať túto sost naučiť sa inteligentný prístup.

Program Outlook umožňuje iba určiť písmo, ktoré sa použije na odpovedanie aj preposielanie e-mailov. Môžete prejsť na „Súbor“> „Možnosti“. Potom v časti „Možnosti programu Outlook“ obráťte sa na kartu „Pošta“ a kliknite na tlačidlo „Kancelárske potreby a písma ...“. V nasledujúcom okne môžete vidieť tlačidlo „Písmo“ v časti „Odpovedanie alebo preposielanie správ“. Kliknite na ňu a potom môžete nastaviť konkrétnu farbu písma pre odpovedanie a preposielanie e-mailov.

Mnoho používateľov však dúfa, že na odpovedanie alebo preposielanie e-mailov použije inú farbu písma. Aj keď to Outlook neposkytuje žiadne priame funkcie, dá sa to ešte realizovať pomocou kódu VBA. Teraz čítajte ďalej a získate taký kúsok kódu VBA.

Automaticky používať rôzne farby písma na odpovedanie a preposielanie e-mailov

1. Pre akotart, spustiť aplikáciu Outlook.
2. Potom spustite editor VBA s odkazom na „Ako spustiť kód VBA v programe Outlook".
3. Ďalej v súlade s „Ako pridať objekt Library Odkaz vo VBA“, Pridať odkaz na„ MS Word Object Library “.
4. Následne skopírujte nasledujúci kód do projektu „ThisOutlookSession“.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. Po tom, restart Outlook aktivovať toto makro.
6. Nakoniec to môžete vyskúšať.

• Vyberte alebo otvorte e-mail.
• Potom kliknite na tlačidlo „Odpovedať“. V odpovedi na e-mail môžete napísať niektoré slová do tela. Farba písma musí byť ružová.
• Alebo kliknite na tlačidlo „Odpovedať všetkým“. Do novej pošty „Odpovedať na všetky“ zadajte slová do tela. Farba písma je určite zelená.
• Podobne kliknite na tlačidlo „Poslať ďalej“. V pošte na preposielanie budú nové slová zobrazené modrou farbou.

Využite spoľahlivý softvér

V prípade Výhľadová korupcia, Most používatelia sa skôr uchýlia k softvéru na obnovenie Outlooku. Na trhu je k dispozícii veľké množstvo takýchto programov. A niektoré z nich sú dokonca zadarmo. Mali by ste si však dať pozor na tie z neznámych zdrojov, pretože môžu súčasný prípad zhoršovať a zhoršovať. Mali by ste využiť spoľahlivý a skúsený nástroj, napríklad DataNumen Outlook Repair.

Úvod autora:

Shirley Zhang je expertkou na obnovu dát v DataNumen, Inc., ktorá je svetovým lídrom v oblasti technológií obnovy dát, vrátane poškodený sql a výhľadové softvérové ​​produkty na opravu. Pre viac informácií navštívte www.datanumen. S