3 spôsoby makra na rýchlu konverziu vašich dokumentov programu Word na PDF Súbory

V tomto článku sa zameriame na to, aby sme vám poskytli 3 makrá, ktoré môžete použiť na rýchlu konverziu dokumentov programu Word pdf súbory.

V programe Word 2003 je na paneli s ponukami ikona. Jediným kliknutím môžu používatelia okamžite spustiť okno „Uložiť ako“ a uložiť dokument do pdf formát.

Ako si však všimnete, rozloženie v programe Word 2010 sa veľmi mení. Používatelia musia kliknúť na kartu „Súbor“ a potom na príkaz „Uložiť ako“, aby sa spustilo okno „Uložiť ako“. Pred kliknutím na tlačidlo „Uložiť“ musíte navyše manuálne zvoliť typ uloženia.

So všetkými tými kliknutiami to nie je dosť rýchle. Preto by sme v tomto príspevku radi ukázali makro spôsob, ako to urobiť.

Makro 1: Rýchlo spustite okno „Uložiť ako“

1. Najprv kliknite na kartu „Vývojár“ a potom na príkaz „Visual Basic“, čím otvoríte editor VBA. Samozrejme, dve kliknutia je potrebné vykonať, keď je karta „Vývojár“ už zobrazená. Alternatívnym spôsobom je stlačiť kombináciu klávesov „Alt+F11“.
2. Po druhé, kliknite na „Normálny“ projekt.
3. Po tretie, kliknite na „Vložiť“ a potom v zozname vyberte „Modul“.
4. Teraz dvakrát kliknite na modul, čím zobrazíte oblasť úprav.
5. Ďalej vložte nasledujúce kódy:

Sub TriggerSaveAsWindow()
  Dim dlgSaveAs As Dialog
 
  Set dlgSaveAs = Dialogs(wdDialogFileSaveAs)
  With dlgSaveAs
    .Format = wdFormatPDF
    .Show
    .Execute
  End With
End Sub

6. Potom kliknite na „Spustiť“.

Teraz sa zobrazí okno „Uložiť ako“. Typ uloženia je už nastavený na pdf. Zostáva už len kliknúť na tlačidlo „Uložiť“. Toto makro vám v prípade potreby umožní zmeniť názov súboru.

Makro 2: Priame ukladanie súborov programu Word do PDF

V prípade, že niektorí ľudia chcú súbor uložiť priamo do pdf bez úpravy názvu súboru je tu potrebné makro.

1. Najskôr zopakujte prvé 4 kroky vyššie.
2. Ďalej namiesto toho prilepte nasledujúce kódy:

'Directly save Word file as Pdf and aumatically open it.
Sub DirectlySaveDocxToPdf()
  Dim objDoc As Document
 
  Set objDoc = ActiveDocument
  objDoc.ExportAsFixedFormat _
    OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
    ExportFormat:=wdExportFormatPDF, OpenAfterExport:=True, OptimizeFor:=wdExportOptimizeForPrint, _
    Range:=wdExportAllDocument, Item:=wdExportDocumentContent
End Sub

3. Podobne kliknite na „Spustiť“.

Makro 3: Dávková konverzia súborov Word DOCX do PDF

1. Najskôr umiestnite všetky súbory docx do jedného priečinka.
2. Podľa vyššie uvedených pokynov otvorte oblasť úprav.
3. Potom vložte nasledujúce makro:

Sub BatchConvertDocxToPDF()
  Dim objDoc As Document
  Dim strFile As String, strFolder As String
 
  'Initialization
  strFolder = "C:\Users\Test\Desktop\Test Files\"
  strFile = Dir(strFolder & "*.docx", vbNormal)
 
  'Precess each file in the file folder and convert them to pdf.
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=strFolder & strFile)
 
    objDoc.ExportAsFixedFormat _
      OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
      ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False, OptimizeFor:=wdExportOptimizeForPrint, _
      Range:=wdExportAllDocument, Item:=wdExportDocumentContent
 
    objDoc.Close
    strFile = Dir()
  Wend
End Sub

4. Nikdy nezabudnite kliknúť na tlačidlo „Spustiť“.

Poznámky: V kódoch “strFolder = “C: \ Users \ Test \ Desktop \ Testovať súbory \”“,„„C: \ Users \ Test \ Desktop \ Test Files \“ ” je cesta k súboru v priečinku. Nezabudnite to zodpovedajúcim spôsobom zmeniť.

Po spustení tohto makra sa súbory PDF uložia do rovnakého priečinka, kde sa nachádzajú dokumenty programu Word.

Zabezpečte súbory, ako môžete

Existujú preventívne opatrenia a tiež opatrenia po katastrofe na záchranu poškodených súborov. Ak pravidelne zálohujete svoje súbory, obnovenie pôvodného súboru je hračka. Pravdou je, že len málo ľudí sa dokáže držať svojho plánu zálohovania, čím sa zvyšuje riziko straty cenných údajov. Za takýchto okolností je čas uchýliť sa k pokročilému... Nástroj na opravu poškodenia programu Word.

Úvod autora:

Vera Chen je expertka na obnovu dát v DataNumen, Inc., ktorá je svetovým lídrom v oblasti technológií obnovy dát, vrátane poškodený Excel xlsx opraviť a pdf oprava softvérových produktov. Pre viac informácií navštívte www.datanumen. S