Как быстро удалить недействительные адреса получателей недоставленных писем из контактов Outlook

При отправке электронных писем на недействительные адреса получателей вы будете получать уведомления о недоставке. В этом случае, если вы захотите удалить эти адреса электронной почты из контактов, вы можете использовать метод, описанный в этой статье.

Вы когда-нибудь получали недоставленные уведомления по электронной почте со списком недействительных адресов электронной почты? Как правило, вы будете получать такие электронные письма после отправки электронной почты на недействительные адреса получателей. В этой ситуации обычно рекомендуется удалить эти адреса электронной почты из контактов Outlook, чтобы предотвратить случайную отправку им писем в следующий раз. Теперь, в дальнейшем, мы поделимся с вами быстрым решением, чтобы получить его.

Удалить недействительные адреса получателей недоставленных писем из контактов

1. Для начала в окне Outlook нажмите «Alt + F11», чтобы открыть редактор VBA.
2. Затем вы можете поместить следующий код VBA в неиспользуемый проект или модуль.

Sub RemoveUndeliverableEmailAddressesfromContacts()
    Dim objSelection As Outlook.Selection
    Dim objContacts As Outlook.Items
    Dim objMail As Outlook.MailItem
    Dim i, n As Long
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim strEmailAddress As String
    Dim strFilter As String
    Dim objFoundContact As Outlook.ContactItem
 
    'Get selected emails
    Set objSelection = Application.ActiveExplorer.Selection
    'Get the contacts
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items
 
    On Error Resume Next
    For Each objMail In objSelection
        objMail.Display
 
        Set objWordDocument = objMail.GetInspector.WordEditor
        Set objWordApp = objWordDocument.Application
        Set objSearchRange = objWordDocument.Range
 
        'Extract email addresses via wildcards
        With objWordApp.Selection.Find
            .Text = "[A-z,0-9]{1,}\@[A-z,0-9,.]{1,}"
            .MatchWildcards = True
            .Execute
        End With
 
        While objWordApp.Selection.Find.Found
              strEmailAddress = objWordApp.Selection.Text
 
              'Remove the invalid email addresses from the associated contacts
              strFilter = "[Email1Address] = " & strEmailAddress
              Set objFoundContact = objContacts.Find(strFilter)
              If Not (objFoundContact Is Nothing) Then
                 With objFoundContact
                     .Email1Address = ""
                     .Email1DisplayName = ""
                     .Save
                 End With
                 strFilter = ""
                 Set objFoundContact = Nothing
              Else
                 strFilter = "[Email2Address] = " & strEmailAddress
                 Set objFoundContact = objContacts.Find(strFilter)
                 If Not (objFoundContact Is Nothing) Then
                    With objFoundContact
                        .Email2Address = ""
                        .Email2DisplayName = ""
                        .Save
                    End With
                    strFilter = ""
                    Set objFoundContact = Nothing
                 Else
                    strFilter = "[Email3Address] = " & strEmailAddress
                    Set objFoundContact = objContacts.Find(strFilter)
                    If Not (objFoundContact Is Nothing) Then
                       With objFoundContact
                           .Email3Address = ""
                           .Email3DisplayName = ""
                           .Save
                       End With
                       strFilter = ""
                       Set objFoundContact = Nothing
                    End If
                End If
             End If
 
             objWordApp.Selection.Find.Execute
        Wend
 
       objMail.Close olDiscard
    Next
 
    MsgBox "Completed!", vbInformation
End Sub

3. После этого закройте текущее окно.
4. Позже добавьте новый макрос на панель быстрого доступа. Вы можете обратиться к статье – «Как запустить код VBA в Outlook».
5. Наконец, вы можете запустить этот макрос, выполнив следующие действия:

• В первую очередь выберите сообщения электронной почты «Недоставленные».
• Затем щелкните макрос на панели быстрого доступа.
• Когда макрос завершится, вы получите сообщение «Completed».
• Теперь вы можете проверить связанные контакты, в которых были удалены недействительные адреса электронной почты, как показано на снимке экрана ниже:

Устранение ошибок и повреждений Outlook

Как мы все знаем, Outlook может столкнуться с проблемами и повреждениями по разным причинам. Следовательно, если вы новичок в Outlook, вам лучше принять некоторые эффективные меры предосторожности, такие как периодическое резервное копирование данных, использование мощного и надежного Восстановление Outlook полезность, как DataNumen Outlook Repair, И так далее.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая восстановить sql и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com