Как быстро распечатать все вложения изображений электронной почты Outlook только на одной странице

Перспективные решения 29 сентября, 2025
Поделись сейчас:

Чтобы сэкономить чернила и бумагу для принтера, некоторые пользователи хотят печатать все изображения, прикрепленные к электронному письму, только на одной странице, а не по одному изображению на странице. Теперь в этой статье мы расскажем, как это реализовать.

Как мы все знаем, печать изображений приводит к расходу чернил принтера. Таким образом, чтобы сэкономить чернила и бумагу для принтера, возможно, вы предпочитаете печатать много прикрепленных изображений на одной странице, а не печатать изображения на отдельных страницах. Хотя Outlook не предлагает такой функции, вы все равно можете реализовать ее следующими способами.

Быстрая печать всех вложений изображений электронной почты Outlook только на одной странице

Печать всех вложений изображений электронной почты Outlook только на одной странице

  1. К start с, запустите приложение Outlook.
  2. Затем в окне Outlook нажмите на клавиши «Alt + F11».
  3. Далее вы попадете в окно «Microsoft Visual Basic для приложений», в котором вы должны сначала включить «Microsoft Word Object Lib».rary ».
  4. После этого нужно открыть модуль, который не используется.
  5. Затем скопируйте и вставьте следующий код VBA в этот модуль.
Sub PrintAllImageAttachmentsOnOnePage()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim objTempMail As Outlook.MailItem
    Dim objTempDocument As Word.Document
    Dim objWordApp As Word.Application
    Dim strImage As String
    Dim objImage As Word.InlineShape
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
       'Create a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       Set objTempDocument = objTempMail.GetInspector.WordEditor
       Set objWordApp = objTempDocument.Application
 
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.attachments
           'Get the Image attachments, instead of inserted Images
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          strImage = "E:\" & objAttachment.filename
                          objAttachment.SaveAsFile strImage
 
                          'Insert the images into the temp mail
                          Set objImage = objWordApp.Selection.InlineShapes.AddPicture(filename:=strImage, LinkToFile:=False, SaveWithDocument:=True)
                          objWordApp.Selection.TypeText Text:=" "
 
                          'shrink the images to insure that they are on one page
                          objImage.ScaleHeight = 20
                          objImage.ScaleWidth = 20
 
                          Kill strImage
             End Select
           End If
       Next
 
       objTempMail.PrintOut
       objTempMail.Close olDiscard
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

Код VBA - печать всех вложений изображений электронной почты Outlook только на одной странице

  1. Позже вы можете вернуться к списку адресов электронной почты. Выберите или откройте электронное письмо, вложения с изображениями которого вы хотите распечатать.
  2. Затем запустите этот макрос. В текущем окне макроса просто нажмите клавишу «F5» или щелкните значок «Выполнить» на панели инструментов.
  3. Наконец, когда макрос завершит работу, все вложения с изображениями исходного письма будут распечатаны на одной странице, как показано на следующем снимке экрана:Изображения только на одной странице

Работа с поврежденными файлами Outlook

Поскольку в вашем Outlook хранится все больше и больше данных, ваш файл Outlook становится все более уязвимым. Это может быть скомпрометировано из-за различных внутренних и внешних факторов. Кроме того, трудно предсказать повреждение Outlook. Итак, что вы можете сделать, так это обеспечить немедленное и эффективное восстановление при обнаружении повреждений Outlook. Например, вы должны иметь специализированный ремонт PST инструмент, как DataNumen Outlook Repair поблизости. Он будет сканировать и восстанавливать поврежденные файлы, как ветерок.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая оправляться Sql Server и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com

Поделись сейчас:

Комментарии закрыты.