Как быстро экспортировать информацию о размере всех папок в файле PST в файл Excel

Перспективные решения 29 сентября, 2025

Если вы хотите проверить информацию о размере каждой папки в файле PST, вы можете использовать метод, представленный в этой статье. Он быстро экспортирует информацию о размере всех папок в файле PST в файл Excel.

Если ваш PST-файл слишком велик, вы можете проверить размер каждой папки. Это поможет вам легко определить, какие из них больше, и сделать подходящее архивирование на основе размера. В общем, чтобы проверить размер папки, вы можете просто щелкнуть правой кнопкой мыши папку и выбрать «Свойства». В новом всплывающем диалоговом окне вы можете нажать кнопку «Размер папки». Однако, если вы создали много папок, проверять информацию о размере вручную по отдельности довольно проблематично. Итак, если вы хотите получить информацию о размере всех папок в файле PST, вы можете использовать следующий код VBA. Он экспортирует все имена папок и информацию о размере в файл Excel за один раз.

Экспорт информации о размере всех папок в файле PST в файл Excel

Для начала запустите приложение Outlook.
Затем перейдите на вкладку «Разработчик» и нажмите кнопку «Visual Basic» или нажмите клавиши «Alt + F11», чтобы получить доступ к редактору VBA.
Затем в окне «Microsoft Visual Basic для приложений» откройте неиспользуемый модуль.
Затем скопируйте и вставьте в этот модуль следующие коды VBA.

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

После этого вы должны установить низкий уровень безопасности макросов Outlook.
В конце концов, вы можете попробовать.

Нажмите клавишу F5 в текущем окне макроса.
Затем вам будет предложено выбрать файл PST, как показано на следующем изображении:
После выбора исходного файла Outlook начнет экспортировать информацию о размере в Excel.
После завершения макроса вы получите сообщение, как на снимке экрана ниже.
Наконец, вы сможете найти файл Excel в предопределенной локальной папке. Файл Excel будет выглядеть следующим образом:

Работа с частыми ошибками PST

Поскольку Outlook подвержен ошибкам, вы, возможно, когда-либо сталкивались со многими проблемами в своем Outlook. Чтобы лучше и гибче справляться с неприятными проблемами PST, рекомендуется иметь поблизости опытную и надежную утилиту исправления, например DataNumen Outlook Repair, Это в состоянии исправить PST проблемы как ветер.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая SQL Server проходили реабилитацию и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com