Как быстро экспортировать электронную почту Outlook в виде файла изображения

Перспективные решения 29 сентября, 2025
Поделись сейчас:

Некоторые пользователи хотели бы экспортировать электронную почту Outlook в виде файла изображения, например файла jpg. Поэтому в этой статье мы познакомим вас, как получить его с помощью кода Outlook VBA.

Вы, должно быть, изучили различные приемы экспорта электронной почты в виде текстового файла, документа Word и так далее. Тогда как насчет экспорта электронной почты в виде изображения, такого как файл JPG? Судя по всему, в Outlook такой функции нет. Но в дальнейшем мы поделимся с вами быстрым средством.

Быстро экспортировать электронную почту Outlook в виде файла изображения

Быстро экспортировать электронную почту Outlook в виде файла изображения

  1. Для насtart, запустите приложение Outlook.
  2. Затем в главном окне Outlook получите доступ к редактору VBA в соответствии со статьей — «Как запустить код VBA в Outlook».
  3. Затем включите «MS Word Object Librarу» и «МС PowerPoint Объектная библиотекаrary», ссылаясь на статью – «Как добавить объектную библиотекуrary Ссылка в VBA».
  4. Затем скопируйте и вставьте следующий код VBA в пустой модуль.
Sub ExportEmailAsImage()
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim strWordDocument As String
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim objDocumentRange As Word.Range
    Dim objPowerPointApp As PowerPoint.Application
    Dim objPresentation As PowerPoint.Presentation
    Dim objShape As PowerPoint.Shape
 
    On Error Resume Next
    'Export the email as Word document
    Set objMail = Outlook.Application.ActiveExplorer.Selection(1)
    strFileName = Replace(objMail.Subject, "/", " ")
    strFileName = Replace(strFileName, "\", " ")
    strFileName = Replace(strFileName, ":", "")
    strFileName = Replace(strFileName, "?", " ")
    strFileName = Replace(strFileName, Chr(34), " ")
    strWordDocument = Environ("Temp") & "\" & strFileName & ".doc"
 
    objMail.SaveAs strWordDocument, olDoc

    Set objWordApp = CreateObject("Word.Application")
    Set objWordDocument = objWordApp.Documents.Open(strWordDocument)
    objWordApp.Visible = True
 
    objWordApp.Selection.Find.ClearFormatting
    objWordApp.Selection.Find.Replacement.ClearFormatting
 
    With objWordApp.Selection.Find
        .Text = "^p^p"
        .Replacement.Text = "^p"
        .Wrap = wdFindContinue
    End With
 
    'Insert the document into a PowerPoint Presentation slide as an object
    objWordApp.Selection.Find.Execute Replace:=wdReplaceAll
    Set objDocumentRange = objWordDocument.Range()
    objDocumentRange.Font.Name = "Calibri"
    objDocumentRange.Font.Size = 10
    objWordDocument.Close True
    objWordApp.Quit
 
    Set objPowerPointApp = CreateObject("PowerPoint.Application")
    Set objPresentation = objPowerPointApp.Presentations.Add
    objPowerPointApp.Visible = msoTrue
 
    With objPresentation
        .PageSetup.SlideHeight = 792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
 
    'Export the slide
    With objPresentation.Slides(1)
         Set objShape = .Shapes.AddOLEObject(0, 0, 612, 792, , strWordDocument)
        .Export "E:\Email_" & strFileName & ".jpg", "JPG"
    End With
 
    objPresentation.Saved = msoTrue
    objPresentation.Close
    objPowerPointApp.Quit
End Sub
  1. После этого нужно добавить макрос на панель быстрого доступа.
  2. Впоследствии вы можете закрыть редактор VBA.
  3. Позже выберите электронное письмо и нажмите кнопку макроса на панели быстрого доступа.Запуск макроса через панель быстрого доступа
  4. Когда макрос завершится, вы можете перейти в предопределенную локальную папку, чтобы найти экспортированный файл изображения из этого письма.Экспортированный файл изображения

Получить данные Outlook из поврежденного файла

Вы можете сильно разочароваться, если ваш файл Outlook будет серьезно поврежден. В этом случае вы приступите к извлечению данных Outlook из скомпрометированного файла. Некоторые пользователи склонны использовать инструмент восстановления папки «Входящие». Тем не менее, мost времени, это не будет иметь последствий. Поэтому лучше держать грозный и надежный PST-исправление инструмент, такой как DataNumen Outlook Repair. Он может сканировать поврежденный файл и без проблем получить максимум данных.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая исправить мдф и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com

Поделись сейчас:

Комментарии закрыты.