Как быстро прикрепить определенные слайды PowerPoint Презентация на вашу электронную почту Outlook

Если вы хотите извлечь определенные слайды из PowerPoint презентацию в отдельную новую презентацию и прикрепить ее к электронному письму Outlook, вы можете использовать способ, описанный в этой статье.

Вместо присоединения всего PowerPoint презентации к электронному письму, если вы хотите прикрепить определенные слайды презентации, как правило, вам необходимо сначала скопировать определенные слайды в новую презентацию. Это слишком хлопотно. Поэтому здесь мы покажем вам метод, который может реализовать это за один раз.

Прикрепите определенные слайды PowerPoint Презентация на электронную почту

1. Прежде всего, откройте конкретный PowerPoint презентация.
2. Затем в PowerPoint окно приложения, нажмите клавиши «Alt + F11», чтобы получить доступ к редактору VBA.
3. Затем в новом окне создайте новый модуль, нажав «Вставить» > «Модуль».
4. Затем скопируйте и вставьте следующий код VBA в этот модуль.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. После этого можно закрыть текущее окно.
6. Позже перейдите в «Файл»> «Параметры»> «Панель быстрого доступа», чтобы добавить новый макрос на панель быстрого доступа.
7. Наконец, вы можете попробовать этот макрос.

• Для насtart, выберите конкретные слайды, которые вы хотите извлечь.
• Затем нажмите кнопку макроса на панели быстрого доступа.
• Сразу же появится электронное письмо Outlook, в котором есть PowerPoint презентация, извлеченная из исходной презентации.

Используйте эффективный инструмент восстановления

Как мы все знаем, Outlook наделен встроенной утилитой восстановления — Скэнпст. Тем не менее, он может просто справиться с небольшими сбоями в Outlook. Если то, с чем вы столкнулись, является серьезным повреждением, оно не будет иметь последствий. В этот момент у вас нет другого выбора, кроме как вернуться к другому мощному и надежному инструменту восстановления, например DataNumen Outlook Repair. С его помощью вы сможете спасти свой поврежденный файл Outlook.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая поврежденный мдф и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com