Как выполнить пакетный экспорт нескольких электронных писем Outlook в один документ Word через VBA

Перспективные решения 29 сентября, 2025
Поделись сейчас:

Если вы хотите выполнить пакетный экспорт нескольких электронных писем Outlook в один текстовый документ, вы можете использовать код VBA, показанный в этой статье. Это может помочь вам выполнить эту задачу в течение нескольких секунд.

Я когда-либо рассказывал, как преобразовать электронную почту Outlook в документ Word в своей предыдущей статье — «2 эффективных метода преобразования электронной почты Outlook в документ WordОднако оба способа, упомянутые в той статье, окажутся бесполезными, если вам нужно экспортировать множество электронных писем в один документ Word. Поэтому здесь мы расскажем вам о другом способе. Читайте дальше, чтобы узнать его подробнее.

Пакетный экспорт нескольких электронных писем Outlook в один документ Word через VBA

Пакетный экспорт нескольких электронных писем Outlook в один документ Word

  1. Для начала запустите программу Outlook.
  2. Затем, после входа в главное окно Outlook, вам нужно нажать клавиши «Alt + F11».
  3. Далее вы получите доступ к редактору Outlook VBA, в котором вам нужно открыть пустой модуль.
  4. Затем скопируйте приведенный ниже код VBA в открытое окно модуля.
Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

Код VBA - пакетный экспорт нескольких электронных писем Outlook в один документ Word

  1. После этого вам лучше добавить этот новый проект VBA на панель быстрого доступа или на ленту.
  2. В конце концов, вы можете попробовать.
  • Во-первых, выберите несколько электронных писем Outlook.
  • Затем найдите и нажмите на недавно добавленную кнопку макроса.
  • После того, как вам будет предложено «Завершить», вы можете перейти к предопределенной локальной папке, чтобы найти новый документ Word.
  • Откройте этот документ, в котором вы можете увидеть, что все выбранные электронные письма были экспортированы.

Держите под рукой мощное средство восстановления

Несмотря на многочисленные функции, Outlook по-прежнему не может быть застрахован от ошибок. Если вы привыкли оставлять ошибки в покое, а их куча, то сбой Outlook обязательно произойдет. В этот момент важно вернуться к мощному и эффективному инструменту восстановления, такому как DataNumen Outlook Repair. Он хорошо разбирается в PST-исправление. Пока с ним, вам больше не нужно беспокоиться о потере данных Outlook.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая поврежденный мдф и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com

Поделись сейчас:

Комментарии закрыты.