Как автоматически установить другое время напоминания для собраний Outlook в разных цветовых категориях

Если вы классифицируете собрания Outlook по цветовым категориям и хотите установить разное время напоминания для собраний в разных цветовых категориях, вы можете обратиться к этой статье. Здесь мы научим вас реализовать это с помощью Outlook VBA.

Например, вы делите встречи на две группы. Одна относится к цветовой категории «Вне офиса», поскольку место проведения встречи находится слишком далеко, а другая — к цветовой категории «В офисе», поскольку место проведения находится прямо здесь. Теперь вы хотите, чтобы Outlook автоматически устанавливал время напоминания для «вне офиса» за 1 час до начала, а для «в офисе» — за 15 минут до начала. Учитывая это требование, далее мы представим быстрый способ решения.

Автоматически устанавливать разные напоминания для встреч в разных цветовых категориях

1. Для начала запустите приложение Outlook.
2. Затем нажмите клавиши «Alt + F11», чтобы открыть окно редактора VBA.
3. Затем в следующем окне скопируйте и вставьте приведенный ниже код VBA в проект «ThisOutlookSession».

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Позже вам нужно будет перейти в подпрограмму «Application_Startup» и нажать клавишу «F5», чтобы запустить этот макрос.
5. С тех пор каждый раз, когда новое собрание добавляется в календарь по умолчанию или вы меняете существующее собрание, Outlook автоматически проверяет категории собрания и автоматически устанавливает другое время напоминания.

Устранение ошибок Outlook

В Outlook время от времени могут возникать различные проблемы. Поэтому крайне важно, чтобы пользователи научились справляться с неполадками Outlook. Для начала лучше регулярно создавать резервные копии данных Outlook. Кроме того, если позволяют средства, рекомендуется хранить резервную копию. Восстановление Outlook инструмент рядом, например DataNumen Outlook Repair. Он может сканировать ваш PST-файл, чтобы выяснить проблемы Outlook, а затем легко решить их.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая sql восстановление и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com