Как автоматически отключить гиперссылки во входящих сообщениях электронной почты Outlook от неизвестных отправителей

Перспективные решения 29 сентября, 2025
Поделись сейчас:

Чтобы заблокировать вредоносные ссылки, вам лучше настроить Outlook на автоматическое отключение гиперссылок во входящих электронных письмах от неизвестных отправителей. В этой статье будет показан фрагмент кода VBA, который поможет вам получить его как пробку.

Многие пользователи жаловались, что вирусы, переносимые по электронной почте, атаковали их файл Outlook. Чаще всего это происходит потому, что они с готовностью доверяют этим электронным письмам от неизвестных отправителей. Поэтому они скачивают или кликают по гиперссылкам в письмах. Теперь, в дальнейшем, мы поделимся методом. Он может позволить Outlook автоматически отключать гиперссылки входящих писем от неизвестных отправителей. Если у вас есть такие потребности, пожалуйста, читайте дальше, чтобы получить более подробную информацию.Автоматическое отключение гиперссылок во входящих сообщениях электронной почты Outlook от неизвестных отправителей

Автоматическое отключение гиперссылок во входящих сообщениях электронной почты от неизвестных отправителей

  1. Для насtarт, в Outlook, перейдите в редактор VBA с помощью «Alt + F11».
  2. Затем на новом экране добавьте объект «Регулярные выражения MS VBScript» в соответствии с п.ost Как добавить объектную библиотекуrary Ссылка в VBA».
  3. Затем скопируйте и вставьте следующий код в проект ThisOutlookSession.
Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'Occurs when new mail arrives in your Inbox
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As MailItem
    Dim objContacts As Outlook.Items
    Dim strFilter As String
    Dim objFoundContact As Outlook.ContactItem
    Dim bUnknownSender As Boolean
    Dim objRegExp As Object
    Dim objFoundResults As Object
    Dim i, n As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Check if the sender is in your default Contact folder
       Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items
       For i = 1 To 3
           strFilter = "[Email" & i & "Address] = " & objMail.SenderEmailAddress
           Set objFoundContact = objContacts.Find(strFilter)
           If Not (objFoundContact Is Nothing) Then
              bUnknownSender = False
              Exit For
           End If
       Next
       If objFoundContact Is Nothing Then
          bUnknownSender = True
       End If
 
       'If the sender is unknown
       If bUnknownSender = True Then
          'Find the urls within "<a href=" tags in HTMLbody of Mail
          Set objRegExp = CreateObject("vbscript.RegExp")
          With objRegExp
               .Pattern = "<?href\s*=\s*[""'].+?[""'][^>]*?"
               .IgnoreCase = True
               .Global = True
          End With
 
          If objRegExp.Test(objMail.HTMLBody) Then
             Set objFoundResults = objRegExp.Execute(objMail.HTMLBody)
             For n = 1 To objFoundResults.Count
                 'Disable the hyperlinks in HTMLbody
                 objMail.HTMLBody = Replace(objMail.HTMLBody, objFoundResults.Item(n - 1).Value, "")
             Next
          End If
 
          'Save the mail
          objMail.Save
       End If
    End If
End Sub

Код VBA - автоматическое отключение гиперссылок во входящих электронных письмах от неизвестных отправителей

  1. После этого активируйте этот макрос либо по restart Outlook или нажав кнопку «F5» в «Application_Starтуп».
  2. С тех пор каждый раз, когда электронное письмо, пришедшее от отправителя, который не хранится в папке «Контакты» по умолчанию, попадает в папку «Входящие», Outlook автоматически отключает в нем гиперссылки.Автоматическое отключение гиперссылок

Несколько важных вопросов в Outlook Protection

Поскольку Outlook подвержен повреждениям, защитить файл Outlook довольно сложно. Здесь мы перечислим несколько обязательных элементов защиты данных Outlook. Прежде всего, вам необходимо регулярно создавать резервные копии данных Outlook. Кроме того, вам важно остерегаться всех потенциальных рисков, таких как вредоносные вложения или гиперссылки. И последнее, но не менее важное: вы должны заранее подготовить мощный инструмент исправления Outlook, например DataNumen Outlook Repair. Обязательно пригодится, когда понадобится восстановить PST файл, но инструмент восстановления папки «Входящие» не работает.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая поврежденный мдф и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com

Поделись сейчас:

Комментарии закрыты.