2 метода быстрого подсчета писем по отправителю в Outlook

Если вы хотите подсчитать электронные письма по отправителю, вы можете обратиться к этой статье. Здесь мы покажем вам 2 быстрых подхода.

Чтоб знать мost активный отправитель для вас, вы можете захотеть подсчитать электронные письма отправителем. Хотя Outlook не предоставляет прямой функции для этого, вы все же можете найти некоторые обходные пути, такие как следующий метод 1. Если вы считаете, что метод 1 слишком утомителен, вы можете выбрать метод 2. Он намного эффективнее в что он использует VBA для быстрого подсчета электронных писем по отправителю и экспорта подсчетов в Excel. Теперь читайте подробно об этих двух способах. Здесь мы возьмем электронные письма в папке «Входящие» для примера.

Метод 1: получить количество после группировки элементов по полю «От»

1. Для начала запустите приложение Outlook.
2. Затем откройте папку «Входящие».
3. Далее перейдите на вкладку «Вид».
4. Затем выберите «От» в группе «Расположение».
5. Сразу все элементы папки «Входящие» были разделены на разные группы в соответствии с разными отправителями.
6. Теперь, чтобы подсчитать элементы от определенного отправителя, вы можете выбрать все элементы в соответствующей группе и нажать клавишу «Ввод». Во всплывающем предупреждении вы можете увидеть количество.

Это означает довольно просто, но подсчет элементов на самом деле включает в себя другие типы элементов, такие как приглашения на собрания, запросы на выполнение задач и квитанции, а не только подсчеты электронной почты. Таким образом, если вы хотите подсчитывать только электронные письма, вы можете использовать следующий способ.

Способ 2: подсчет писем по отправителю с помощью Outlook VBA

1. Для насtart, нажмите клавиши «Alt + F11» в Outlook.
2. Затем включите «MS Excel Object Librarу» в соответствии с «Как добавить объектную библиотекуrary Ссылка в VBA».
3. Затем скопируйте приведенный ниже код в неиспользуемый модуль.

Sub CountInboxEmailsbySender()
    Dim objDictionary As Object
    Dim objInbox As Outlook.Folder
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim strSender As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varSenders As Variant
    Dim varItemCounts As Variant
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
 
    For i = objInbox.Items.Count To 1 Step -1
        If objInbox.Items(i).Class = olMail Then
           Set objMail = objInbox.Items(i)
           strSender = objMail.SenderEmailAddress
 
           If objDictionary.Exists(strSender) Then
              objDictionary.Item(strSender) = objDictionary.Item(strSender) + 1
           Else
              objDictionary.Add strSender, 1
           End If
        End If
    Next

    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Sender"
         .Cells(1, 2) = "Count"
    End With
 
    varSenders = objDictionary.Keys
    varItemCounts = objDictionary.Items
 
    For i = LBound(varSenders) To UBound(varSenders)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
        With objExcelWorksheet
             .Cells(nLastRow, 1) = varSenders(i)
             .Cells(nLastRow, 2) = varItemCounts(i)
        End With
    Next
 
    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

3. После этого нажмите клавишу «F5».
4. Когда макрос завершится, появится новый файл Excel.
5. Как видите, он содержит количество входящих писем от разных отправителей.

Избавьтесь от разочаровывающих проблем с Outlook

Возможно, вы когда-либо сталкивались со многими проблемами в Outlook. Чтобы эффективно их решать, вам может понадобиться универсальный и мощный способ. Но на самом деле такого метода нет. Что вы можете сделать, так это остерегаться своих собственных операций в Outlook и регулярно делать резервные копии. Конечно, если возможно, мы предлагаем вам лучше держать под рукой опытный инструмент исправления, например DataNumen Outlook Repair. Он может исправить различные проблемы с PST и восстановить поврежденный файл PST файл как ветер.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая оправляться Sql Server и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com