Как быстро вставить имена получателей в тело письма в Outlook

Перспективные решения 29 сентября, 2025
Поделись сейчас:

Если вы хотите быстро вставить имена получателей в тело при составлении электронного письма, вы можете прочитать эту статью. Здесь мы познакомим вас с удобным методом.

Иногда вам может потребоваться ввести имена всех получателей в тело при составлении электронного письма. Несомненно, извлекать и вставлять имена в тело вручную одно за другим довольно утомительно и громоздко. Поэтому, чтобы помочь вам сделать это быстро, здесь мы поделимся с вами эффективным средством. Читайте дальше, чтобы получить подробные шаги.

Вставьте имена получателей в тело письма

  1. Для насtart, войдите в редактор VBA через «Alt + F11».
  2. Затем в окне «Microsoft Visual Basic для приложений» включите «MS Word Object Lib».rarу» в соответствии с «Как добавить объектную библиотекуrary Ссылка в VBA».
  3. Затем скопируйте приведенный ниже код VBA в пустой модуль.
Sub CopyRecipientNamesToBody()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim strRecipAddress As String
    Dim strRecipName As String
    Dim objContacts As Outlook.Items
    Dim i As Integer
    Dim strFilter As String
    Dim objFoundContact As Outlook.ContactItem
    Dim strRecipNames As String
    Dim objMailDocument As Word.Document
 
    'Get the current email
    Set objMail = Application.ActiveInspector.CurrentItem
    objMail.Recipients.ResolveAll
 
    For Each objRecipient In objMail.Recipients
        strRecipAddress = objRecipient.Address
 
        'Get the corresponding contact name
        Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items
        For i = 1 To 3
            strFilter = "[Email" & i & "Address] = " & strRecipAddress
            Set objFoundContact = objContacts.Find(strFilter)
            If Not (objFoundContact Is Nothing) Then
               strRecipNames = strRecipNames & objFoundContact.FullName & vbCr
               Exit For
            End If
        Next
 
        'If there isn't associated contact
        'Extract name from email address
        If objFoundContact Is Nothing Then
           strRecipName = Split(strRecipAddress, "@")(0)
           strRecipName = UCase(Left(strRecipName, 1)) & Right(strRecipName, Len(strRecipName) - 1)
           strRecipNames = strRecipNames & strRecipName & vbCr
        End If
    Next
 
    'Insert the names at the beginning of email
    Set objMailDocument = objMail.GetInspector.WordEditor
    objMailDocument.Range(0, 0).InsertAfter strRecipNames
End Sub

Код VBA — вставка имен получателей в тело электронной почты

  1. Затем добавьте этот макрос на панель быстрого доступа окна сообщения в соответствии с необязательным шагом в «Как запустить код VBA в Outlook».
  2. После этого выйдите из окна.
  3. Наконец, сделайте снимок.
  • Прежде всего, составьте электронное письмо и заполните получателей.
  • Затем нажмите кнопку макроса на панели быстрого доступа.Нажмите кнопку макроса
  • Когда макрос завершится, имена получателей будут вставлены в тело письма, как показано на рисунке ниже.Вставленные имена получателей в теле письма

Защита от повреждения Outlook

Так как Outlook уязвим, его трудно защитить от повреждений. Без сомнения, вы должны неохотно встречаться с PST-повреждение. Поэтому вам лучше принять некоторые эффективные меры предосторожности. Например, вам нужно делать согласованные резервные копии данных для Outlook, знать, как использовать инструмент восстановления папки «Входящие», а также держать под рукой мощный внешний инструмент, такой как DataNumen Outlook Repair.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая SQL Server фиксировать и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com

Поделись сейчас:

Комментарии закрыты.