Cum să setați automat Outlook online sau offline în funcție de programul dvs. de lucru

Unii utilizatori ar dori ca Outlook să comute automat între starea online și offline, în funcție de programul lor de lucru. Deci, în acest articol, vă vom împărtăși o metodă rapidă.

De fapt, setarea Outlook online sau offline este foarte ușoară. Pentru a transforma Outlook în starea offline, puteți doar să comutați la fila „Trimite/Primire” și să apăsați butonul „Lucrează offline”. Și pentru a reveni la starea online, pur și simplu apăsați din nou acest buton. Cu toate acestea, unii utilizatori speră că Outlook poate trece automat la starea offline atunci când nu mai este în programul de lucru și să revină la online în timpul orelor de lucru. Deși Outlook nu oferă o astfel de caracteristică, puteți utiliza în continuare următorul cod VBA pentru a o realiza.

Setați automat Outlook online sau offline în funcție de programul dvs. de lucru

1. De la bun început, start aplicația dvs. Outlook.
2. Apoi, după ce obțineți acces la Outlook, ar trebui să deschideți folderul Sarcini.
3. În continuare, ar trebui să creați un element de sarcină recurent zilnic.

• Faceți clic pe butonul „Nouă sarcină” din panglică.
• Apoi introduceți „Offline” în linia de subiect al sarcinii.
• Apoi faceți clic pe butonul „Recurență” din fila „Sarcina”.
• În caseta de dialog pop-up, selectați modelul de recurență „Zilnic”, activați „Fără dată de încheiere” și apăsați „OK”.
• Apoi, ar trebui să activați un memento la „5:00 PM”.
• În cele din urmă apăsați butonul „Salvați și închideți”.

4. Ulterior, trebuie să creați o altă sarcină zilnică recurentă numită „Online” și să activați un memento la „8:00 AM”, afișat ca imaginea de mai jos:
5. După aceea, în fereastra principală a Outlook, apăsați butoanele tastei „Alt + F11”.
6. În continuare, veți avea acces la editorul Outlook VBA, în care trebuie să găsiți și să deschideți proiectul „ThisOutlookSession”.
7. Mai târziu copiați următorul cod VBA în acest proiect.

Dim objNameSpace As Outlook.NameSpace

'Set Online/Offline Status on Outlook Startup
Private Sub Application_Startup()
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    'If now is before 8:00 AM or after 5:00 PM on Outlook startup
    If Now() < DateSerial(Year(Now), Month(Now), Day(Now)) + #8:00:00 AM# Or Now() > DateSerial(Year(Now), Month(Now), Day(Now)) + #5:00:00 PM# Then
 
       'If Outlook is online
       If objNameSpace.Offline = False Then
          'set it offline
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
 
       'If now is between 8:00 AM and 5:00 PM
    Else
 
       'If Outlook is offline
       If objNameSpace.Offline = True Then
          'Set it online
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
    End If
End Sub

'Change Online/Offline Status at Specific Time
Private Sub Application_Reminder(ByVal Item As Object)
    Dim objOfflineTask As Outlook.TaskItem
    Dim objOnlineTask As Outlook.TaskItem
 
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    If TypeOf Item Is TaskItem Then
       If Item.Subject = "Offline" Then
          Set objOfflineTask = Item
 
          'If Outlook is online when "Offline" task reminder alerts
          If objNameSpace.Offline = False Then
             'Set Outlook offline
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          'Clear the reminder by marking task complete
          objOfflineTask.MarkComplete
 
       ElseIf Item.Subject = "Online" Then
          Set objOnlineTask = Item
 
          'If Outlook is offline when "Online" task reminder alerts
          If objNameSpace.Offline = True Then
             'Set Outlook online
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          objOnlineTask.MarkComplete
 
       End If
    End If
End Sub

8. În cele din urmă, puteți restart Outlook pentru a activa această macrocomandă.
9. De acum înainte, Outlook va fi online în timpul programului de lucru și va trece automat la starea offline în afara programului de lucru.

Ultima dvs. soluție în cazul în care Outlook se blochează

Deși Outlook se mândrește cu mai multe funcții, Outlook încă nu se poate feri de erori și daune. Dar nu intrați în panică. Atâta timp cât luați suficiente măsuri de precauție, vă puteți proteja datele Outlook în mod eficient. De exemplu, ar trebui să faceți o copie de rezervă a fișierelor PST în mod regulat, deoarece backupurile vă vor permite să reveniți PST corupt date. De asemenea, păstrarea unui instrument puternic de reparații, cum ar fi DataNumen Outlook Repair, este de asemenea o chestiune de necesitate.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv repara mdf și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com