Cum să exportați rapid numărul total de articole din fiecare folder Outlook în Excel

Dacă doriți să obțineți un raport despre numărul de elemente din fiecare folder Outlook, puteți utiliza metoda introdusă în acest articol. Va face rapid numărarea și va exporta rezultatele într-un fișier Excel.

În articolul meu anterior – „Cum să obțineți rapid numărul total de articole dintr-un folder și toate subfolderele acestuia prin Outlook VBA”, puteți învăța o metodă folosind VBA pentru a obține numărul de elemente dintr-un folder. Cu toate acestea, prin acest mijloc, dacă doriți să numărați elementele din toate folderele, trebuie să selectați fiecare folder și să rulați macrocomanda unul câte unul. E cam plictisitor. Prin urmare, vă vom învăța o altă metodă, care va exporta numărul într-un fișier Excel.

Exportați numărul total de articole din fiecare folder Outlook în Excel

1. La început, lansați programul Outlook.
2. Apoi apăsați butoanele tastei „Alt + F11” în fereastra principală a Outlook.
3. Apoi veți intra în fereastra „Microsoft Visual Basic pentru aplicații”, în care trebuie să deschideți un modul care nu este utilizat.
4. Ulterior, copiați și inserați următorul cod VBA în acest modul.

Public strExcelFile As String
Public objExcelApp As Excel.Application
Public objExcelWorkbook As Excel.Workbook
Public objExcelWorksheet As Excel.Worksheet

Sub Export_CountOfItems_InEachFolder_toExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Create a new Excel file
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Count Items"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Items Count (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderItemCount As Long
    Dim nLastRow As Integer
 
    lCurrentFolderItemCount = objCurrentFolder.Items.Count
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nLastRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nLastRow) = lCurrentFolderItemCount
 
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. După aceea, trebuie să schimbați nivelul de securitate al macrocomenzii Outlook la scăzut.
6. Apoi puteți reveni la macrocomanda nou adăugată și puteți apăsa butonul tasta F5 pentru a rula această macrocomandă.
7. Apoi, trebuie să selectați un fișier PST sursă și să apăsați „OK”.
8. După terminarea macrocomenzii, puteți merge în folderul local predefinit pentru a găsi noul fișier Excel, care va arăta ca următoarea captură de ecran:

Soluționați erorile PST enervante

Poate că ați întâlnit diverse probleme în timpul utilizării Outlook. Pentru a rezolva problemele mici, puteți recurge pur și simplu la instrument de reparare inbox. Cu toate acestea, dacă problemele sunt atât de grave încât au depășit ceea ce poate face instrumentul încorporat, trebuie să utilizați un instrument mai puternic, cum ar fi DataNumen Outlook Repair.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv reparatie mdf și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com