Cum să exportați rapid detaliile tuturor membrilor dintr-un grup de contacte Outlook în Excel

În mod implicit, puteți vedea numai numele membrilor și adresele de e-mail dintr-un grup de contacte. Dacă doriți să obțineți și alte detalii ale membrilor, puteți utiliza modalitatea introdusă în acest articol.

Când faceți dublu clic pe un grup de contacte pentru a-l deschide, în fereastra acestuia, puteți vedea doar numele și adresele de e-mail ale membrilor grupului. Nu puteți obține alte detalii ale membrilor, cum ar fi compania, funcția, numărul de telefon sau adresa comercială etc. În general, pentru a obține aceste detalii, trebuie să găsiți manual contactele corespunzătoare membrilor în folderul Contacte. Este prea supărător. Aici vă vom arăta o bucată de cod VBA, care poate exporta rapid aceste detalii într-un registru de lucru Excel.

Exportați detaliile tuturor membrilor dintr-un grup de contact în Excel

1. Pentru început, lansați aplicația Outlook.
2. Apoi ar trebui să apăsați comenzile rapide „Alt + F11” în fereastra principală a Outlook.
3. Apoi, în noua fereastră „Microsoft Visual Basic for Applications”, trebuie să deschideți un modul care nu este utilizat sau să introduceți direct un modul nou.
4. Ulterior, copiați și inserați următorul cod VBA în acest modul.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. După aceea, pentru o verificare convenabilă, puteți adăuga noul proiect VBA la Bara de instrumente Acces rapid sau panglică.
6. Ulterior setați nivelul de securitate al macrocomenzii Outlook la scăzut.
7. În cele din urmă, puteți încerca.

• Mai întâi, selectați un grup de contacte.
• Apoi apăsați butonul macro din Bara de instrumente Acces rapid sau din panglică.
• Imediat, macro-ul va rula.
• Când se termină, veți primi un mesaj „Terminat!”
• După aceea, puteți merge la folderul local de destinație predefinit, în care puteți găsi un nou fișier Excel.
• Deschideți-l, veți vedea detaliile de contact ale membrilor grupului, cum ar fi următoarea captură de ecran:

Nu intrați în panică în fața problemelor Outlook

Nimeni nu este dispus să accepte problemele Outlook, indiferent de mesajul de eroare pop-up sau corupt Outlook fișier de date. Prin urmare, utilizatorii vor avea tendința de a intra în panică atunci când întâmpină probleme cu Outlook. Dacă vreți să vă păstrați calmul în acest caz, ar trebui să aveți două necesități în mână. Unul este backup-ul actual al datelor Outlook. Celălalt este un software puternic de remediere Outlook, cum ar fi DataNumen Outlook Repair.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv recuperare sql și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com