Cum să atașați rapid diapozitivele specifice ale unui PowerPoint Prezentare pe e-mailul dvs. Outlook

Dacă doriți să extrageți diapozitivele specifice ale unui PowerPoint prezentare la o nouă prezentare separată și atașați-o la un e-mail Outlook, puteți utiliza modul partajat în acest articol.

În loc să atașați un întreg PowerPoint prezentare la un e-mail, dacă doriți să atașați diapozitivele specifice prezentării, în general, trebuie să copiați mai întâi diapozitivele specifice într-o prezentare nouă. Este prea supărător. Prin urmare, aici vă vom arăta o metodă care o poate realiza dintr-o singură mișcare.

Atașați diapozitivele specifice ale a PowerPoint Prezentare la un e-mail

1. Mai întâi, deschideți specificul PowerPoint prezentare.
2. Apoi, în PowerPoint fereastra aplicației, apăsați tastele „Alt + F11” pentru a accesa editorul VBA.
3. Apoi, în noua fereastră, creați un modul nou apăsând „Inserare” > „Modul”.
4. Ulterior, copiați și inserați următorul cod VBA în acest modul.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. După aceea, puteți închide fereastra curentă.
6. Mai târziu, accesați „Fișier” > „Opțiuni” > „Bară de instrumente Acces rapid” pentru a adăuga noua macrocomandă la Bara de instrumente Acces rapid.
7. În cele din urmă, puteți încerca această macrocomandă.

• Pentru noitart, selectați diapozitivele specifice pe care doriți să le extrageți.
• Apoi, faceți clic pe butonul macro din Bara de instrumente Acces rapid.
• Imediat, va apărea un e-mail Outlook, în care există un PowerPoint prezentare care este extrasă din prezentarea sursă.

Utilizați un instrument eficient de recuperare

După cum știm cu toții, Outlook este dotat cu un utilitar de reparare încorporat - Scanpst. Cu toate acestea, poate face față pur și simplu micilor erori în Outlook. Dacă ceea ce te confrunți este o pagubă serioasă, nu va produce efecte. În acel moment, nu aveți de ales decât să recurgeți la un alt instrument de reparații puternic și de încredere, cum ar fi DataNumen Outlook Repair. Cu el, veți fi capabil să vă salvați fișierul Outlook corupt.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv mdf corupt și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com