Cum să atașați rapid ultimul fișier modificat dintr-un folder Windows la e-mailul dvs. Outlook

Uneori, poate doriți să găsiți și să atașați rapid ultimul fișier modificat dintr-un anumit folder Windows la un e-mail Outlook. În acest caz, puteți utiliza metoda introdusă în acest articol.

Unii utilizatori doresc să permită Outlook să afle rapid și să atașeze ultimul fișier modificat dintr-un folder Windows la un e-mail, cum ar fi most fișier creat, modificat sau salvat recent. Cu toate acestea, Outlook nu oferă o funcție atât de directă și nativă. Prin urmare, în cele ce urmează, vom expune o bucată de cod VBA, care o poate realiza cu ușurință.

Atașați ultimul fișier modificat dintr-un folder Windows la e-mail

1. De la bun început, ar trebui să lansați aplicația Outlook.
2. Apoi, după ce intri în fereastra principală Outlook, poți apăsa butoanele tastei „Alt + F11”.
3. În continuare, veți accesa cu succes fereastra editorului Outlook VBA.
4. Ulterior, ar trebui să găsiți și să deschideți un modul care nu este utilizat.
5. Și apoi copiați și inserați următorul cod VBA în fereastra acestui modul.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. După aceea, puteți ieși din fereastra actuală a editorului VBA și puteți continua să adăugați noua macrocomandă la Bara de instrumente Acces rapid sau panglica din fereastra Mesaj.
7. Mai târziu, trebuie să schimbați nivelul de securitate al macrocomenzii Outlook la scăzut.
8. În cele din urmă poți încerca.

• În primul rând, creați și compuneți un nou e-mail Outlook ca de obicei.
• Apoi apăsați butonul macro din Bara de instrumente Acces rapid, ca în imaginea de mai jos:
• În continuare, vi se va cere să selectați un folder Windows sursă și să apăsați „OK”.
• Dacă există un astfel de fișier în folderul Windows selectat, veți primi o solicitare precum următoarea captură de ecran:
• Când apăsați „Da”, acest fișier va fi atașat imediat.

Rezolvați problemele Outlook cât mai curând posibil

Ori de câte ori întâmpinați probleme cu Outlook, se recomandă să le rezolvați cât mai curând posibil. În această situație, mai bine pregătiți un robust Remediere Outlook instrument în avans, cum ar fi DataNumen Outlook Repair. Este capabil să repare erorile PST și să vă salveze datele Outlook în mod eficient.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv mdf corupt și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com