Cum să setați un timp de memento prestabilit diferit pentru diferite tipuri de elemente marcate în Outlook

În mod implicit, Outlook va folosi automat ora de memento implicită a sarcinilor pentru toate tipurile de elemente marcate. Cu toate acestea, dacă doriți să utilizați timp de memento diferit pentru articolele semnalate în funcție de tipul de articol, puteți consulta metoda introdusă în acest articol.

Outlook vă permite să setați ora de memento implicită pentru toate articolele semnalate, indiferent de tipul articolului. Puteți accesa meniul „Fișier” și faceți clic pe „Opțiuni”. Apoi, în fereastra „Opțiuni Outlook”, puteți vedea opțiunea „Timp de memento implicit” din fila „Sarcini”, așa cum se arată în următoarea captură de ecran.

Cu toate acestea, majoritatea utilizatorilor speră să utilizeze ore de reamintire diferite pentru diferite tipuri de elemente semnalizate, cum ar fi „9:00” pentru e-mailurile semnalizate și „17:30” pentru contactele semnalizate. În cele ce urmează, ne vom concentra pe acest exemplu pentru a introduce o metodă.

Setați un timp de memento prestabilit diferit pentru diferite tipuri de articole marcate

1. Pentru început, lansați aplicația Outlook.
2. Apoi, accesați editorul Outlook VBA cu referire la „Cum să rulați codul VBA în Outlook".
3. În fereastra ulterioară „Microsoft Visual Basic for Applications”, copiați următorul cod în proiectul „ThisOutlookSession”.

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. După aceea, reporniți Outlook pentru a activa această macrocomandă.
5. De acum înainte, de fiecare dată când semnalați un e-mail, ora de memento va fi setată la „10:00” la data limită a semnalării.
6. Și când semnalați un contact, ora de memento va fi setată la „17:30” la data limită a semnalării.

Abordați problemele Outlook în mod flexibil

Poți întâmpina tot felul de probleme în Outlook. Așadar, trebuie să înveți câteva măsuri pentru a le rezolva în avans. De exemplu, dacă Outlook repornește des, trebuie să repari Office sau să dezactivezi programele de completare terțe etc. Sau, dacă fișierul PST din Outlook este compromis, poți încerca mai întâi... instrument de reparare inbox. Când eșuează, puteți continua să recurgeți la un instrument extern puternic, cum ar fi DataNumen Outlook Repair.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv recuperare mdf și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com