Cum să utilizați automat diferite culori de font pentru a răspunde și a redirecționa e-mail-uri cu Outlook VBA

În mod implicit, nu puteți lăsa Outlook să folosească automat culori diferite de font pentru a răspunde și a redirecționa e-mail-uri. Prin urmare, dacă aveți o astfel de cerință, puteți citi această post pentru a învăța o abordare inteligentă.

Outlook vă permite doar să specificați un font folosit atât pentru a răspunde, cât și pentru a redirecționa e-mailuri. Puteți accesa „Fișier” > „Opțiuni”. Apoi, în „Opțiuni Outlook”, accesați fila „Poștă” și faceți clic pe butonul „Papetărie și fonturi...”. În fereastra ulterioară, puteți vedea butonul „Font” în „Răspuns sau redirecționare mesaje”. Faceți clic pe acesta și apoi puteți seta o anumită culoare de font pentru a răspunde și a redirecționa e-mailurile.

Cu toate acestea, mulți utilizatori speră să folosească diferite culori de font pentru a răspunde sau a redirecționa e-mailuri. Deși Outlook nu oferă nicio caracteristică directă pentru aceasta, poate fi realizată cu codul VBA. Acum, citiți mai departe pentru a obține o astfel de bucată de cod VBA.

Utilizați automat diferite culori de font pentru a răspunde și a redirecționa e-mailuri

1. Pentru noitart, lansați aplicația Outlook.
2. Apoi, declanșați editorul VBA cu referire la „Cum să rulați codul VBA în Outlook".
3. În continuare, în conformitate cu „Cum să adăugați un obiect Library Referință în VBA„, adăugați referința la „MS Word Object Library ”.
4. Ulterior, copiați următorul cod în proiectul „ThisOutlookSession”.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. După aceea, restart Outlook pentru a activa această macrocomandă.
6. În sfârșit, puteți încerca.

• Selectați sau deschideți un e-mail.
• Apoi, faceți clic pe butonul „Răspuns”. În răspunsul la e-mail, puteți introduce câteva cuvinte în text. Culoarea fontului trebuie să fie roz.
• Sau faceți clic pe butonul „Răspunde tuturor”. În noul e-mail „Răspuns tuturor”, introduceți cuvintele în text. Culoarea fontului este cu siguranță verde.
• În mod similar, faceți clic pe butonul „Înainte”. În mesajul de redirecționare, cuvintele noi vor fi afișate cu albastru.

Recurgeți la un software de încredere

În caz de corupție Outlook, Most utilizatorii tind să recurgă la software-ul de recuperare Outlook. Există o mare cantitate de astfel de programe disponibile pe piață. Iar unele dintre ele sunt chiar gratuite. Cu toate acestea, ar trebui să vă feriți de cei din surse necunoscute, deoarece acestea pot înrăutăți situația actuală. Ar trebui să vă ajutați de un instrument de încredere și cu experiență, cum ar fi DataNumen Outlook Repair.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv sql corupt și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com