Cum să dezactivați automat hyperlinkurile din e-mailurile Outlook primite de la expeditori necunoscuți

Pentru a bloca legăturile rău intenționate, ar fi mai bine să configurați Outlook pentru a dezactiva automat hyperlinkurile din e-mailurile primite de la expeditori necunoscuți. Acest articol va dezvălui o bucată de coduri VBA care vă poate ajuta să o obțineți ca pe un dop.

Mulți utilizatori s-au plâns că virușii transmisi prin e-mail le-au atacat fișierul Outlook. De cele mai multe ori, se datorează faptului că au încredere în acele e-mailuri de la expeditorii necunoscuți. Deci ei descarcă sau dau clic pe hyperlinkurile din e-mailuri. Acum, ulterior, vom împărtăși o metodă. Este capabil să permită Outlook să dezactiveze automat hyperlinkurile e-mailurilor primite de la expeditori necunoscuți. Dacă aveți astfel de nevoi, vă rugăm să citiți mai departe pentru a obține mai multe detalii.

Dezactivați automat hyperlinkurile în e-mailurile primite de la expeditori necunoscuți

1. Pentru început, în Outlook, accesați editorul VBA apăsând combinația de taste „Alt + F11”.
2. Apoi, în noul ecran, adăugați obiectul „MS VBScript Regular Expressions” conform postării „Cum se adaugă o referință la o bibliotecă de obiecte în VBA".
3. Apoi, copiați și inserați următorul cod în proiectul „ThisOutlookSession”.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'Occurs when new mail arrives in your Inbox
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As MailItem
    Dim objContacts As Outlook.Items
    Dim strFilter As String
    Dim objFoundContact As Outlook.ContactItem
    Dim bUnknownSender As Boolean
    Dim objRegExp As Object
    Dim objFoundResults As Object
    Dim i, n As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Check if the sender is in your default Contact folder
       Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items
       For i = 1 To 3
           strFilter = "[Email" & i & "Address] = " & objMail.SenderEmailAddress
           Set objFoundContact = objContacts.Find(strFilter)
           If Not (objFoundContact Is Nothing) Then
              bUnknownSender = False
              Exit For
           End If
       Next
       If objFoundContact Is Nothing Then
          bUnknownSender = True
       End If
 
       'If the sender is unknown
       If bUnknownSender = True Then
          'Find the urls within "<a href=" tags in HTMLbody of Mail
          Set objRegExp = CreateObject("vbscript.RegExp")
          With objRegExp
               .Pattern = "<?href\s*=\s*[""'].+?[""'][^>]*?"
               .IgnoreCase = True
               .Global = True
          End With
 
          If objRegExp.Test(objMail.HTMLBody) Then
             Set objFoundResults = objRegExp.Execute(objMail.HTMLBody)
             For n = 1 To objFoundResults.Count
                 'Disable the hyperlinks in HTMLbody
                 objMail.HTMLBody = Replace(objMail.HTMLBody, objFoundResults.Item(n - 1).Value, "")
             Next
          End If
 
          'Save the mail
          objMail.Save
       End If
    End If
End Sub

4. După aceea, activați această macrocomandă fie repornind Outlook, fie apăsând tasta „F5” din subrutina „Application_Startup”.
5. De atunci, de fiecare dată când un e-mail care vine de la expeditor care nu este stocat în folderul implicit de contact intră în Inbox, Outlook va dezactiva automat hyperlinkurile din acesta.

Câteva chestiuni de necesitate în protecția Outlook

Deoarece Outlook este susceptibil la deteriorare, este destul de dificil să protejați fișierul Outlook. Aici vom enumera câteva elemente obligatorii în timpul protecției datelor Outlook. În primul rând, trebuie să faceți o copie de rezervă a datelor Outlook în mod regulat. În plus, este esențial să fii atent la toate riscurile potențiale, cum ar fi atașamentele rău intenționate sau hyperlinkurile. Nu în ultimul rând, ar trebui să pregătiți în avans un instrument puternic de remediere Outlook, cum ar fi DataNumen Outlook Repair. Cu siguranță vă va fi util atunci când aveți nevoie repara PST fișier, dar instrumentul de reparare a căsuței primite dovedește eșec.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv mdf deteriorat și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com