6 moduri de a păstra atașamentele originale de e-mail atunci când răspundeți în Outlook

Mulți utilizatori speră să își configureze Outlook pentru a păstra atașamentele originale de e-mail atunci când răspund la un e-mail. Acest articol va expune 5 soluții alternative, precum și o modalitate inteligentă, care utilizează VBA pentru a o realiza automat.

Am auzit un număr mare de utilizatori plângându-se că Outlook nu are o funcție nativă pentru a păstra atașamentele originale atunci când răspund la un e-mail. Prin urmare, aici vă vom împărtăși 6 metode, dintre care una este destul de utilă, deoarece folosește VBA pentru a face ca Outlook să atașeze automat atașamentele originale la e-mailul de răspuns. Acum citiți mai departe pentru a le obține în detaliu.

1. Răspundeți cu e-mailul original atașat

Deși Outlook nu oferă o funcție de păstrare a atașamentelor originale de e-mail atunci când răspund la un e-mail, permite utilizatorilor să păstreze atașat e-mailul original. Prin urmare, este o soluție opțională pentru dvs. Puteți merge la „Fișier” > „Opțiuni” > „Poștă” > secțiunea „Răspunsuri și redirecționări” pentru a modifica setările de răspuns. Pentru mai multe detalii, vă sugerăm să consultați articolul meu anterior – „5 pași pentru a răspunde cu atașamentele originale în Outlook”. Dar, dacă tot sperați să păstrați doar atașamentele originale, treceți să învățați celelalte mijloace.

2. Trageți și plasați manual atașamente

1. Pentru început, faceți dublu clic pe un astfel de e-mail sursă pentru a-l deschide într-o fereastră separată.
2. Apoi faceți clic pe butonul „Răspunde”, care va afișa e-mailul de răspuns.
3. În continuare, ar trebui să micșorați ambele ferestre de mesaje până când le puteți vedea în același ecran.
4. După aceea, selectați toate atașamentele din e-mailul original.
5. În cele din urmă, trageți și plasați-le pe linia „Atașată” din e-mailul de răspuns.

3. Copiați și lipiți manual atașamentele

1. În primul rând, după deschiderea e-mailului sursă, selectați toate atașamentele.
2. Apoi faceți clic pe butonul „Copiere” din fila „Atașamente”.
3. După aceea, faceți clic pe butonul „Răspuns” din fila „Mesaj” pentru a deschide un e-mail de răspuns.
4. În cele din urmă, în e-mailul de răspuns, faceți clic pe linia „Atașat” și apăsați butonul „Ctrl + V” pentru a lipi atașamentele copiate anterior.

4. Redirecționați e-mailul și completați destinatarul

1. Mai întâi, selectați un astfel de e-mail și apoi faceți clic pe butonul „Redirecționare” din panglică.
2. În noua fereastră pop-up Mesaj, atașamentele originale sunt păstrate. Acum trebuie să completați câmpul „Către” expeditorului e-mailului original.
3. Opțional, puteți schimba subiectul în funcție de nevoile dvs.

5. Retrimiteți acest e-mail și schimbați destinatarii

1. Pentru început, deschideți e-mailul sursă.
2. Apoi faceți clic pe butonul „Acțiuni” din grupul „Mutare”.
3. Apoi alegeți „Retrimiteți acest mesaj” din lista derulantă.
4. Poate veți primi o alertă care menționează că nu sunteți expeditorul inițial. Doar ignorați-l și apăsați „Da”.
5. În noul e-mail ulterior, ar trebui să modificați câmpul „Către” la expeditorul e-mailului inițial.
6. De asemenea, nu uitați să schimbați contul de trimitere prin e-mail în propriul cont.

6. Adăugați automat atașamente originale prin VBA

Toate abordările menționate mai sus, pentru a fi sincer, sunt soluții alternative. Dacă sperați că Outlook poate păstra automat atașamentele originale atunci când răspundeți, puteți utiliza acest mod.

1. În fereastra principală Outlook, apăsați tastele „Alt + F11”.
2. Apoi, în fereastra „Microsoft Visual Basic for Applications”, copiați codul VBA de mai jos în proiectul „ThisOutlookSession”.

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeName(objExplorer.Selection.Item(1)) = "MailItem" Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeName(Inspector.CurrentItem) = "MailItem" Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when clicking "Reply" button
Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

'Occurs when clicking "Reply All" button
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

Private Sub KeepOriginalAttachments(ByVal objOriginalMail As MailItem, objReply As Object)
    Dim strEnviro As String
    Dim strTempFolder As String
    Dim strFilePath As String
    Dim objAttachment As Outlook.Attachment
 
    'Get the temp folder in Windows
    strEnviro = CStr(Environ("USERPROFILE"))
    strTempFolder = strEnviro & "\AppData\Local\Temp"
 
    For Each objAttachment In objOriginalMail.Attachments
        'Skip the embedded image attachments
        If IsEmbeddedAttachment(objAttachment) = False Then
           strFilePath = strTempFolder & "\" & objAttachment.filename
           objAttachment.SaveAsFile strFilePath
 
           'Attach the temporarily saved attachments to the Reply
           objReply.Attachments.Add strFilePath
 
           'Delete the temporarily saved attachments
           Kill strFilePath
       End If
    Next
End Sub

'Function for checking if an attachment is embedded image attachment
Function IsEmbeddedAttachment(objCurrentAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurrentAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbeddedAttachment = True
    Else
       IsEmbeddedAttachment = False
    End If
End Function

3. Mai târziu semnați această macrocomandă și modificați setările macrocomenzii Outlook pentru a permite macrocomenzile semnate.
4. După aceea, reporniți aplicația Outlook pentru a activa acest proiect VBA.
5. De acum înainte, de fiecare dată când faceți clic pe butonul „Răspunde”. E-mailul de răspuns se va afișa simultan cu atașamentele originale.

Apelați la un instrument de reparare preeminent

Outlook a trecut peste alți clienți de e-mail datorită nenumăratelor sale caracteristici. Dar este încă predispus la corupție. Prin urmare, ar trebui să acordați mai multă atenție sănătății sale. În general, atunci când întâmpinați probleme mici, puteți recurge pur și simplu la utilitarul de remediere încorporat. Cu toate acestea, dacă suferiți de probleme grave, ar fi bine să recurgeți la un instrument mult mai competent, cum ar fi DataNumen Outlook Repair. Poate remediați Outlook dosar într-o clipă.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv remediere sql și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com