3 moduri rapide de a elimina hyperlinkurile din imaginile din documentul Word

În acest articol, am dori să vă expunem 3 moduri rapide de a elimina hyperlinkurile din imaginile din documentul Word.

Uneori, când copiați o imagine online, o găsim încorporată cu un hyperlink. Și într-un document Word, dacă faceți clic accidental pe imagine, vă poate duce la adresa de net a imaginii. Acest lucru nu este doar iritant, dar încurcă efectul vizual al documentului dvs., cum ar fi mai jos:

Prin urmare, alegem să eliminăm hyperlinkurile din imagini pentru a evita un astfel de salt neașteptat de pagină. Începem.

Metoda 1: Eliminați hyperlink dintr-o imagine

1. În primul rând, faceți clic dreapta pe o imagine.
2. Apoi, în meniul contextual, alegeți „Eliminați hyperlink”.

Metoda 2: Eliminați în loturi hyperlinkurile din toate imaginile dintr-un document

Există o modalitate de a elimina toate hyperlinkurile dintr-un document. Mai întâi apăsați „Ctrl+A” pentru a selecta tot conținutul. Apoi apăsați „Ctrl+ Shift+ F9” pentru a elimina toate hyperlinkurile. Pentru informarea dumneavoastră, în acest fel șterge toate hyperlinkurile atât pe imagini, cât și pe texte. Totuși, scopul nostru este să eliminăm hyperlinkurile numai din imagini. Deci, va trebui să folosim o macrocomandă pentru a finaliza lucrarea.

1. În primul rând, apăsați „Alt+ F11” pentru a declanșa editorul VBA în Word.
2. Apoi, în editor, faceți clic pe proiectul „Normal”.
3. Apoi, în bara de meniu, faceți clic pe „Inserați”.
4. Și alegeți „Modul” din meniul derulant.
5. Acum faceți dublu clic pe modul pentru a deschide zona de codare din dreapta și inserați următoarea macrocomandă acolo:

Sub RemoveAllHyperlinksFromPicturesInOneDocument()
  Dim objInlinePicture As InlineShape
  Dim objPicture As Shape
 
  If ActiveDocument.InlineShapes.Count > 0 Then 
    For Each objInlinePicture In ActiveDocument.InlineShapes
      objInlinePicture.Select
 
      While Selection.Hyperlinks.Count > 0
        Selection.Hyperlinks(1).Delete
      Wend 
    Next
  End If

  If ActiveDocument.Shapes.Count > 0 Then 
    For Each objPicture In ActiveDocument.Shapes 
      objPicture.Select
 
      While Selection.Hyperlinks.Count > 0
        Selection.Hyperlinks(1).Delete
      Wend 
    Next 
  End If
End Sub

6. Nu în ultimul rând, faceți clic pe „Run” în bara de meniu pentru a executa coduri.

Metoda 3: Eliminați în loturi hyperlinkurile din imaginile din mai multe documente

1. Înainte de toate, aranjați toate documentele țintă într-un singur dosar.
2. Apoi repetați pașii din metoda 2 pentru a instala și rula următoarea macrocomandă:

Sub RemoveAllHyperlinksFromPicturesInMultipleDocuments()
  Dim objInlinePicture As InlineShape
  Dim objPicture As Shape
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
 
    If ActiveDocument.InlineShapes.Count > 0 Then
      For Each objInlinePicture In ActiveDocument.InlineShapes
        objInlinePicture.Select 
        While Selection.Hyperlinks.Count > 0
          Selection.Hyperlinks(1).Delete
        Wend
      Next
    End If

    If ActiveDocument.Shapes.Count > 0 Then
      For Each objPicture In ActiveDocument.Shapes
        objPicture.Select 
        While Selection.Hyperlinks.Count > 0
          Selection.Hyperlinks(1).Delete
        Wend
      Next
    End If

    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    strFile = Dir()
  Wend
End Sub

3. În fereastra „Răsfoiți” deschisă, alegeți folderul pe care l-ați setat la pasul 1 și faceți clic pe „OK” pentru a continua.

Fiți atenți la operațiunea dvs. în Word

Word nu este ireproșabil, așa că orice operațiune greșită poate declanșa cu ușurință colapsul sau, mai rău, corupția documentului rezultat. Deși puteți acorda mai multă atenție abilităților și obiceiurilor dvs. de operare, puteți achiziționa și un utilitar pentru recuperare doc în prealabil.

Introducerea autorului:

Vera Chen este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv recuperați xls și pdf repararea produselor software. Pentru mai multe informații vizitați www.datanumen.com