În acest articol, ne vom concentra pe a vă oferi 3 macrocomenzi pe care le puteți utiliza pentru a converti rapid documentele Word în pdf fișiere.
În Word 2003, există o pictogramă pe bara de meniu. Cu un singur clic, utilizatorii pot declanșa instantaneu fereastra „Salvare ca” și pot salva documentul pdf format.
Cu toate acestea, după cum observați, aspectul în Word 2010 se schimbă foarte mult. Și utilizatorii trebuie să facă clic pe fila „Fișier”, apoi pe comanda „Salvare ca” pentru a declanșa fereastra „Salvare ca”. Mai mult, trebuie să alegeți manual tipul de salvare înainte de a apăsa butonul „Salvare”.
Cu toate aceste clicuri, nu este suficient de rapid. Prin urmare, în această postare, ne-ar plăcea să vă arătăm metoda macro pentru a face asta.
Macrocomanda 1: Declanșați rapid fereastra „Salvare ca”.
- În primul rând, faceți clic pe fila „Developer”, apoi pe comanda „Visual Basic” pentru a deschide editorul VBA. Desigur, cele 2 clicuri trebuie făcute atunci când fila „Developer” este deja afișată. O altă metodă este să apăsați „Alt+F11”.
- În al doilea rând, faceți clic pe proiect „Normal”.
- În al treilea rând, faceți clic pe „Inserare” și apoi alegeți „Modul” din meniul listei.
- Acum dublu clic pe modul pentru a afișa zona de editare.
- Apoi, lipiți următoarele coduri:
Sub TriggerSaveAsWindow()
Dim dlgSaveAs As Dialog
Set dlgSaveAs = Dialogs(wdDialogFileSaveAs)
With dlgSaveAs
.Format = wdFormatPDF
.Show
.Execute
End With
End Sub
- Apoi faceți clic pe „Run”.
Acum există fereastra „Salvare ca”. Și tipul de salvare este deja în format PDF. Tot ce mai rămâne de făcut este să faceți clic pe butonul „Salvare”. Această macrocomandă vă permite să schimbați numele fișierului, dacă este necesar.
Macro 2: Salvați direct fișiere Word în format PDF
În eventualitatea, unii oameni doresc să salveze fișierul direct în pdf fără a revizui numele fișierului, iată macrocomanda care are nevoie.
- În primul rând, repetă primii 4 pași de mai sus.
- Apoi, lipiți următoarele coduri:
'Directly save Word file as Pdf and aumatically open it.
Sub DirectlySaveDocxToPdf()
Dim objDoc As Document
Set objDoc = ActiveDocument
objDoc.ExportAsFixedFormat _
OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
ExportFormat:=wdExportFormatPDF, OpenAfterExport:=True, OptimizeFor:=wdExportOptimizeForPrint, _
Range:=wdExportAllDocument, Item:=wdExportDocumentContent
End Sub
- În mod similar, faceți clic pe „Run”.
Macro 3: Conversia în lot a fișierelor Word Docx în PDF-uri
- Mai întâi plasați toate fișierele docx într-un singur folder.
- Urmați pașii de mai sus pentru a deschide zona de editare.
- Apoi lipiți macrocomanda de mai jos:
Sub BatchConvertDocxToPDF()
Dim objDoc As Document
Dim strFile As String, strFolder As String
'Initialization
strFolder = "C:\Users\Test\Desktop\Test Files\"
strFile = Dir(strFolder & "*.docx", vbNormal)
'Precess each file in the file folder and convert them to pdf.
While strFile <> ""
Set objDoc = Documents.Open(FileName:=strFolder & strFile)
objDoc.ExportAsFixedFormat _
OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False, OptimizeFor:=wdExportOptimizeForPrint, _
Range:=wdExportAllDocument, Item:=wdExportDocumentContent
objDoc.Close
strFile = Dir()
Wend
End Sub
- Nu uitați niciodată să faceți clic pe butonul „Run”.
notițe: În coduri „strFolder = „C:\Users\Test\Desktop\Test Files\””,„„C:\Utilizatori\Test\Desktop\Fișiere de testare\”” este calea fișierului a folderului. Nu uitați să îl schimbați în consecință.
După rularea acestei macrocomenzi, fișierele PDF vor fi salvate în același folder în care se află documentele Word.
Securizați fișierele cât puteți
Există măsuri preventive și acțiuni post-dezastru pentru a salva fișierele deteriorate. Dacă continuați să faceți copii de rezervă ale fișierelor în mod regulat, recuperarea fișierului original este floare la ureche. Adevărul este că puțini oameni își pot respecta planul de backup, crescând astfel riscul de a pierde date valoroase. În astfel de circumstanțe, este timpul să recurgeți la o soluție avansată. Instrumentul de remediere a corupției documentelor Word.
Introducerea autorului:
Vera Chen este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv reparație Excel xlsx deteriorată și pdf repararea produselor software. Pentru mai multe informații vizitați www.datanumen.com



