3 moduri rapide de a șterge rândurile și coloanele goale din tabelul dvs. Word

În această postare, vă vom explica 3 metode rapide de a șterge rânduri și coloane goale din tabelul Word.

Tabelele sunt esențiale pentru un document, mai ales în deținerea diferitelor tipuri de date. Uneori, un tabel lung poate depăși o pagină și se poate extinde pe mai multe. Deci, odată ce un tabel devine lung și complicat, există măsuri pe care le puteți face pentru a-l simplifica. De exemplu, puteți șterge rândurile și coloanele goale inutile.

Mai jos sunt 3 metode pe care le puteți folosi.

Metoda 1: Ștergeți manual rândurile și coloanele goale

1. În primul rând, selectați un rând sau o coloană în gol.
2. Apoi faceți clic dreapta pentru a obține meniul contextual. În meniu, selectați „Ștergeți rândurile” sau „Ștergeți coloanele” în consecință.

Din păcate, nu puteți selecta mai multe rânduri sau coloane neconsecutive și să le ștergeți împreună în acest fel. Pentru această cerere, puteți consulta articolul nostru anterior: 5 metode rapide pentru a șterge în lot mai multe rânduri sau coloane din tabelul dvs. Word

Metoda 2: Ștergeți în lot toate rândurile și coloanele goale dintr-un tabel

Metoda 1 are o limitare. Așadar, vă vom oferi modalitatea de a elimina în serie rândurile și coloanele dintr-un tabel prin coduri VBA.

1. Pentru început, plasați cursorul în interiorul unui tabel țintă.
2. În al doilea rând, declanșați editorul VBA apăsând „Alt+ F11”.
3. În editor, faceți mai întâi clic pe proiectul „Normal”.
4. Apoi faceți clic pe fila „Inserare” din bara de meniu.
5. În meniul derulant, alegeți „Modul”.
6. Faceți dublu clic pe modul pentru a-l deschide și lipiți următoarele coduri acolo:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. În cele din urmă, faceți clic pe butonul „Run” din bara de meniu sau apăsați pe „F5”.

În câteva secunde, veți elimina toate rândurile și coloanele goale din acel tabel.

Metoda 3: Ștergeți în lot toate rândurile și coloanele goale din toate tabelele dintr-un document

1. În primul rând, repetați pașii din metoda 2 pentru a instala și a rula o macrocomandă.
2. Numai de această dată, înlocuiți macrocomanda cu următoarele:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Recuperați documentul spart

În zilele noastre există mai multe modalități de a recupera datele pierdute. De exemplu, recurgerea la copii de rezervă rămâne întotdeauna prioritatea principală. Dacă acest lucru nu vă satisface nevoia de a recupera cele mai recente informații, puteți încerca... reparatie doc instrument.

Introducerea autorului:

Vera Chen este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv reparare xlsx și pdf repararea produselor software. Pentru mai multe informații vizitați www.datanumen.com