Como exportar rapidamente estatísticas de votação de um e-mail do Outlook para uma planilha do Excel

Se você enviou um e-mail com botões de votação, após os destinatários enviarem suas respostas, você pode querer contar e exportar as estatísticas de votação para uma planilha do Excel. Então, neste post, ensinaremos como alcançá-lo rapidamente.

O Outlook é tão poderoso que oferece até um recurso de “Votação”. Meu artigo anterior “Uso hábil do MS Outlook para votação” ensinou como utilizá-lo de forma eficaz. Além disso, most de tempo, após a votação, você pode exportar as estatísticas de votação para uma planilha do Excel por alguns motivos, como desejar imprimir as estatísticas. Mas o Outlook não oferece suporte a isso por padrão. Assim, a seguir, ensinaremos como realizar isso como uma rolha.

Exportar estatísticas de votação em um e-mail para uma planilha do Excel

1. No início, inicie seu aplicativo Outlook.
2. Então você deve pressionar os botões “Alt + F11” na janela principal do Outlook.
3. Em seguida, na janela “Microsoft Visual Basic for Applications”, você deve habilitar “Microsoft Excel Object Librarvocê”. Clique em “Ferramentas” > “Referência”. Em seguida, na caixa de diálogo pop-up, marque a caixa de seleção na frente do “Microsoft Excel Object Library” e clique em “OK” por último.
4. Depois disso, você pode inserir um novo módulo ou abrir um que não esteja em uso.
5. Posteriormente, copie e cole os seguintes códigos VBA neste módulo.

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

5. Depois disso, para acesso conveniente, é melhor adicionar a nova macro à Barra de Ferramentas de Acesso Rápido.
6. Eventualmente, você pode tentar.

• Em primeiro lugar, selecione um e-mail de origem que contenha botões de votação.
• Em seguida, clique no botão de macro na Barra de Ferramentas de Acesso Rápido.
• Após a execução dessa macro, você pode navegar até a pasta local predefinida, na qual verá uma nova pasta de trabalho do Excel.
• Abra esta pasta de trabalho do Excel. Agora você verá as estatísticas de votação, mostradas na imagem abaixo:

Ninguém pode evitar completamente os erros do Outlook

Embora o Outlook seja dotado de uma variedade de recursos, não existe tal recurso para nos ajudar a evitar erros do Outlook. Todos os tipos de fatores podem causar erros do Outlook. Por exemplo, se você costuma sair do Outlook incorretamente, provavelmente sofrerá Corrupção PST. Nesse cenário, você não tem escolha a não ser usar algumas ferramentas potentes para resgatar seu arquivo PST, como DataNumen Outlook Repair. Ele ganhou muitos elogios devido à sua alta taxa de recuperação.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo mdf corrompido e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com