Como exportar em lote vários e-mails do Outlook para um documento do Word via VBA

Se você deseja exportar em lote vários e-mails do Outlook em um único documento do Word, pode usar o código VBA mostrado neste artigo. Ele pode ajudá-lo a realizar essa tarefa em segundos.

Já apresentei como converter um e-mail do Outlook em um documento do Word em meu artigo anterior – “2 métodos eficazes para converter um e-mail do Outlook em um documento do Word”. No entanto, ambos os 2 meios mencionados naquele post será impotente no caso de você desejar exportar muitos e-mails em lote para um documento do Word. Portanto, aqui vamos ensinar-lhe outra maneira. Agora, continue lendo para obtê-lo detalhadamente.

Exportação em lote de vários e-mails do Outlook para um documento do Word

1. Para% start com, inicie seu programa Outlook.
2. Então, depois de entrar na janela principal do Outlook, você precisa pressionar os botões "Alt + F11".
3. Em seguida, você terá acesso ao editor VBA do Outlook, no qual deverá abrir um módulo em branco.
4. Posteriormente, copie o código VBA abaixo na janela do módulo aberto.

Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Depois disso, é melhor adicionar este novo projeto VBA à barra de ferramentas de acesso rápido ou à faixa de opções.
6. Em última análise, você pode tentar.

• Em primeiro lugar, selecione vários e-mails do Outlook.
• Em seguida, localize e clique no botão de macro recém-adicionado.
• Depois que você for solicitado a “Concluir”, você pode navegar até a pasta local predefinida para encontrar um novo documento do Word.
• Abra este documento, no qual você pode ver que todos os e-mails selecionados foram exportados.

Mantenha uma poderosa ferramenta de recuperação por perto

Independentemente de inúmeras funções, o Outlook ainda não pode estar imune a erros. Se você está acostumado a deixar os erros de lado, com eles se acumulando, o travamento do Outlook ocorrerá definitivamente. Nesse ponto, é fundamental recorrer a uma poderosa e eficaz ferramenta de recuperação, como DataNumen Outlook Repair. É bem versado em correção PST. Enquanto estiver com ele, você não precisará mais se preocupar com a perda de dados do Outlook.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo mdf corrompido e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com