Como criar rapidamente uma regra do Outlook para bloquear os remetentes de vários e-mails

Se você deseja criar uma regra para bloquear os remetentes de vários e-mails selecionados, geralmente é necessário primeiro anotar os remetentes e, em seguida, criar uma regra manualmente. É bastante problemático. Portanto, aqui compartilharemos um método muito mais rápido para obtê-lo com um clique.

Alguns usuários acham que o recurso “ant-spam” embutido no Outlook não é tão eficaz quanto eles esperam. Portanto, eles estão acostumados a criar regras do Outlook para bloquear os remetentes. Agora, a seguir, apresentaremos um método rápido para criar uma regra para bloquear os remetentes de vários emails.

Crie rapidamente uma regra para bloquear remetentes de vários e-mails

1. Para comotart, inicie o aplicativo Outlook.
2. Em seguida, entre na janela do editor VBA através do atalho “Alt + F11”.
3. Em seguida, na nova janela, coloque o seguinte código VBA em um módulo não utilizado.

Sub CreateRuleForBlockingMultipleSenders()
    Dim objRules As Outlook.Rules
    Dim objRule As Outlook.Rule
    Dim objMoveRuleAction As Outlook.MoveOrCopyRuleAction
    Dim objFromCondition As Outlook.ToOrFromRuleCondition
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim objJunkFolder As Outlook.Folder
 
    Set objRules = Application.Session.DefaultStore.GetRules()
    'Create a rule
    Set objRule = objRules.Create("Block Senders", olRuleReceive)
    Set objFromCondition = objRule.Conditions.From
 
    'Get the selected emails
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    'Get Junk Email folder
    Set objJunkFolder = Outlook.Application.Session.GetDefaultFolder(olFolderJunk)
 
    For i = objSelection.Count To 1 Step -1
        If objSelection.Item(i).Class = olMail Then
 
           Set objMail = objSelection.Item(i)
 
           'Add the email senders to rule condition
           With objFromCondition
                .Enabled = True
                .Recipients.Add objMail.SenderEmailAddress
                .Recipients.ResolveAll
           End With
 
           'Move the emails from blocked senders to Junk Email folder
           Set objMoveRuleAction = objRule.Actions.MoveToFolder
           With objMoveRuleAction
                .Enabled = True
                .Folder = objJunkFolder
           End With
         End If
    Next
 
    objRules.Save
End Sub

4. Depois disso, de acordo com “Como executar o código VBA no seu Outlook“, adicione esta macro à barra de ferramentas de acesso rápido ou à faixa de opções.
5. Posteriormente, saia do editor VBA normalmente.
6. Por fim, siga as etapas a seguir para tentar.

• Em primeiro lugar, selecione os e-mails cujos remetentes você deseja bloquear.
• Em seguida, clique no botão nova macro.
• Após o término da macro, você pode acessar o menu “Arquivo” e clicar no botão “Gerenciar regras e alertas” para verificar a regra recém-adicionada, conforme a imagem abaixo.

Mantenha e-mails maliciosos na baía

Não importa qual cliente de e-mail você use, você deve receber frequentemente e-mails de remetentes desconhecidos. Most dos e-mails podem ser spams publicitários e até mesmo conter macros maliciosas. Eles podem danificar seu arquivo do Outlook em um instante. Portanto, no Outlook, você deve tomar medidas eficazes para bloquear os e-mails desconhecidos. Além disso, se você puder pagar, é aconselhável preparar uma poderosa ferramenta de recuperação de PST, como DataNumen Outlook Repair. Pode reparar o Outlook arquivo sem suar a camisa, não importa o quão gravemente esteja danificado.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo recuperação sql e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com