Como agrupar vários arquivos iCalendar (.ics) abertos em seu Outlook

Se você tiver muitos arquivos iCalendar (.ics) em sua unidade local e quiser abri-los em lote no Outlook, leia este artigo. Aqui vamos ensiná-lo a utilizar o código VBA para realizá-lo.

Normalmente, para abrir um arquivo iCalendar (.ics) em seu Outlook, você pode facilmente usar o recurso “Importar”. No entanto, se você deseja abrir muitos em lote, “Importar” é inútil, pois não oferece suporte para selecionar mais de um arquivo de uma vez. Portanto, você tem que usar outras abordagens.

Se esses arquivos ics estiverem armazenados na mesma pasta local, você pode selecioná-los e pressionar a tecla “Enter” para abri-los em massa. Mas, se eles estiverem localizados em pastas diferentes em uma unidade, a maneira acima também é inútil. Nesse caso, você pode usar o método a seguir, que pode processar todas as pastas em uma pasta principal recursivamente. Agora, continue lendo para obter mais detalhes.

Lote para abrir vários arquivos iCalendar (.ics)

1. Para começar, abra o programa Outlook.
2. Em seguida, toque em “Alt + F11” para acessar o editor VBA.
3. Depois disso, na nova janela, insira o seguinte código VBA em um módulo.

Sub BatchOpenMultipleICalendarFiles()
    Dim objShell, objWindowsFolder As Object
    Dim strWindowsFolder As String
 
    'Select a Windows Folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"
       Call LoopFolders(strWindowsFolder)
 
       MsgBox "Completed!", vbInformation + vbOKOnly, "Open iCalendar Files"
    End If
End Sub

Sub LoopFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objICalendarFile As Object
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    'Open each iCalendar file
    For Each objFile In objFolder.Files
        If LCase(objFileSystem.GetExtensionName(objFile)) = "ics" Then
           Set objICalendarFile = objFile
           On Error Resume Next
           Application.GetNamespace("MAPI").OpenSharedFolder objICalendarFile.Path
        End If
    Next
 
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
              Call LoopFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

4. Em seguida, mova o cursor na sub-rotina “BatchOpenMultipleICalendarFiles”.
5. Por fim, pressione “F5” para acionar esta macro.
6. Posteriormente, na caixa de diálogo pop-up, selecione uma pasta ou unidade do Windows onde os arquivos do iCalendar estão armazenados.
7. Ao receber a mensagem “Concluído”, acesse o painel “Calendário” no Outlook.
8. Você pode ver que todos os arquivos do iCalendar naquela pasta do Windows estão lá, como na captura de tela a seguir:

Prepare uma formidável ferramenta de correção de PST nas proximidades

Talvez você saiba que o Outlook é propenso a erros e corrupção. Assim, é aconselhável fazer backup de seus arquivos de dados do Outlook em intervalos regulares. Dessa forma, mesmo que seu arquivo do Outlook seja comprometido, você pode simplesmente recuperar dados valiosos do Outlook dos backups. No entanto, se não houver tal backup, você precisará usar uma ferramenta de reparo notável, como DataNumen Outlook Repair. Ele pode ajudá-lo a corrigir Outlook questões como uma rolha.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo recuperar mdf e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com