6 maneiras de manter os anexos de e-mail originais ao responder no Outlook

Muitos usuários esperam configurar seu Outlook para manter os anexos de e-mail originais ao responder um e-mail. Este artigo irá expor 5 soluções alternativas, bem como uma maneira inteligente, que é usar o VBA para realizá-lo automaticamente.

Tenho ouvido um grande número de usuários reclamando que o Outlook não possui um recurso nativo para manter os anexos originais ao responder um e-mail. Portanto, aqui vamos compartilhar 6 métodos, um dos quais é bastante útil, pois é usar o VBA para fazer o Outlook anexar automaticamente os anexos originais ao email de resposta. Agora continue lendo para obtê-los em detalhes.

1. Responder com o e-mail original anexado

Embora o Outlook não forneça um recurso para manter anexos de e-mail originais ao responder um e-mail, ele permite que os usuários mantenham o e-mail original anexado. Portanto, é uma solução opcional para você. Você pode ir para a seção “Arquivo” > “Opções” > “Correio” > “Respostas e encaminhamentos” para alterar as configurações de resposta. Para mais detalhes, sugere-se que você consulte meu artigo anterior – “5 etapas para responder com anexos originais no Outlook”. Mas, se você ainda espera manter apenas os anexos originais, avance para aprender os outros meios.

2. Arrastar e soltar anexos manualmente

1. Para% start com, clique duas vezes em tal e-mail de origem para abri-lo em sua própria janela.
2. Em seguida, clique no botão "Responder", que exibirá o e-mail de resposta.
3. Em seguida, você deve encolher as duas janelas de mensagens até poder vê-las na mesma tela.
4. Depois disso, selecione todos os anexos no e-mail original.
5. Por fim, arraste e solte-os na linha “Anexado” no e-mail de resposta.

3. Copiar e colar anexos manualmente

1. Em primeiro lugar, após abrir o e-mail de origem, selecione todos os anexos.
2. Em seguida, clique no botão “Copiar” na guia “Anexos”.
3. Depois disso, clique no botão “Responder” na guia “Mensagem” para abrir um e-mail de resposta.
4. Por fim, no e-mail de resposta, clique na linha “Anexado” e pressione o botão “Ctrl + V” para colar os anexos copiados anteriormente.

4. Encaminhar e-mail e preencher o destinatário

1. Primeiro, selecione esse e-mail e clique no botão "Avançar" na faixa de opções.
2. Na nova janela pop-up Message, os anexos originais são mantidos. Agora você precisa preencher o campo "Para" para o remetente do e-mail original.
3. Opcionalmente, você pode alterar o assunto de acordo com suas necessidades.

5. Reenvie este e-mail e altere os destinatários

1. Para começar, abra o e-mail de origem.
2. Em seguida, clique no botão “Ações” no grupo “Mover”.
3. Em seguida, escolha “Reenviar esta mensagem” na lista suspensa.
4. Talvez você receba um alerta mencionando que você não é o remetente original. Apenas ignore e clique em “Sim”.
5. No novo e-mail subsequente, deverá modificar o campo “Para” para o remetente do e-mail original.
6. Além disso, lembre-se de alterar o envio usando a conta de e-mail para sua própria conta.

6. Adicionar anexos originais automaticamente via VBA

Todas as abordagens mencionadas acima, para ser honesto, são soluções alternativas. Se você espera que o Outlook possa manter automaticamente os anexos originais ao responder, você pode usar este método.

1. Na janela principal do Outlook, pressione as teclas “Alt + F11”.
2. Em seguida, na janela “Microsoft Visual Basic for Applications”, copie o código VBA abaixo para o projeto “ThisOutlookSession”.

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeName(objExplorer.Selection.Item(1)) = "MailItem" Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeName(Inspector.CurrentItem) = "MailItem" Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when clicking "Reply" button
Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

'Occurs when clicking "Reply All" button
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

Private Sub KeepOriginalAttachments(ByVal objOriginalMail As MailItem, objReply As Object)
    Dim strEnviro As String
    Dim strTempFolder As String
    Dim strFilePath As String
    Dim objAttachment As Outlook.Attachment
 
    'Get the temp folder in Windows
    strEnviro = CStr(Environ("USERPROFILE"))
    strTempFolder = strEnviro & "\AppData\Local\Temp"
 
    For Each objAttachment In objOriginalMail.Attachments
        'Skip the embedded image attachments
        If IsEmbeddedAttachment(objAttachment) = False Then
           strFilePath = strTempFolder & "\" & objAttachment.filename
           objAttachment.SaveAsFile strFilePath
 
           'Attach the temporarily saved attachments to the Reply
           objReply.Attachments.Add strFilePath
 
           'Delete the temporarily saved attachments
           Kill strFilePath
       End If
    Next
End Sub

'Function for checking if an attachment is embedded image attachment
Function IsEmbeddedAttachment(objCurrentAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurrentAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbeddedAttachment = True
    Else
       IsEmbeddedAttachment = False
    End If
End Function

3. Posteriormente, assine esta macro e altere as configurações de macro do Outlook para permitir as macros assinadas.
4. Depois disso restarPeça ao seu aplicativo Outlook para ativar este projeto VBA.
5. A partir de agora, toda vez que você clicar no botão "Responder". O e-mail de resposta será exibido com os anexos originais de uma só vez.

Recorra a uma ferramenta de reparo preeminente

O Outlook superou outros clientes de e-mail devido a seus inúmeros recursos. Mas ainda é propenso à corrupção. Portanto, você deve prestar mais atenção à sua saúde. Em geral, ao encontrar pequenos problemas, você pode simplesmente recorrer ao utilitário de correção integrado. No entanto, se você tiver problemas sérios, é melhor recorrer a uma ferramenta muito mais eficiente, como DataNumen Outlook Repair. Pode corrigir Outlook arquivo em um instante.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo correção de sql e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com