3 maneiras de macro para converter rapidamente seus documentos do Word em PDF Arquivos

Neste artigo, vamos nos concentrar em fornecer 3 macros que você pode usar para converter rapidamente documentos do Word em pdf arquivos.

No Word 2003, há um ícone na barra de menu. Com um único clique, os usuários podem acionar a janela “Salvar como” instantaneamente e salvar o documento em pdf formato.

No entanto, como você pode notar, o layout do Word 2010 muda muito. E os usuários precisam clicar na guia “Arquivo” e depois no comando “Salvar como” para acionar a janela “Salvar como”. Além disso, você deve escolher manualmente o tipo de salvamento antes de clicar no botão “Salvar”.

Com tantos cliques, não é rápido o suficiente. Portanto, neste post, gostaríamos de mostrar a maneira mais eficiente de fazer isso, utilizando macros.

Macro 1: acione a janela “Salvar como” rapidamente

1. Primeiramente, clique na guia "Desenvolvedor" e, em seguida, no comando "Visual Basic" para abrir o editor VBA. É importante que esses dois cliques sejam feitos com a guia "Desenvolvedor" já visível. Outra opção é pressionar "Alt + F11".
2. Em segundo lugar, clique no projeto “Normal”.
3. Em terceiro lugar, clique em “Inserir” e escolha “Módulo” no menu da lista.
4. Agora clique duas vezes no módulo para mostrar a área de edição.
5. Em seguida, cole os seguintes códigos:

Sub TriggerSaveAsWindow()
  Dim dlgSaveAs As Dialog
 
  Set dlgSaveAs = Dialogs(wdDialogFileSaveAs)
  With dlgSaveAs
    .Format = wdFormatPDF
    .Show
    .Execute
  End With
End Sub

6. Em seguida, clique em “Executar”.

Agora, a janela "Salvar como" será exibida. O tipo de arquivo salvo já está em PDF. Basta clicar no botão "Salvar". Esta macro permite que você altere o nome do arquivo, se necessário.

Macro 2: Salvar arquivos do Word diretamente em PDF

No caso de algumas pessoas quererem salvar o arquivo diretamente para pdf sem revisar o nome do arquivo, aqui está a macro necessária.

1. Em primeiro lugar, repita os primeiros 4 passos acima.
2. Em seguida, cole os seguintes códigos:

'Directly save Word file as Pdf and aumatically open it.
Sub DirectlySaveDocxToPdf()
  Dim objDoc As Document
 
  Set objDoc = ActiveDocument
  objDoc.ExportAsFixedFormat _
    OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
    ExportFormat:=wdExportFormatPDF, OpenAfterExport:=True, OptimizeFor:=wdExportOptimizeForPrint, _
    Range:=wdExportAllDocument, Item:=wdExportDocumentContent
End Sub

3. Da mesma forma, clique em “Executar”.

Macro 3: Converter em lote arquivos Word (.ocx) para PDFs

1. Coloque todos os arquivos docx em uma pasta primeiro.
2. Siga as etapas acima para abrir a área de edição.
3. Em seguida cole a macro abaixo:

Sub BatchConvertDocxToPDF()
  Dim objDoc As Document
  Dim strFile As String, strFolder As String
 
  'Initialization
  strFolder = "C:\Users\Test\Desktop\Test Files\"
  strFile = Dir(strFolder & "*.docx", vbNormal)
 
  'Precess each file in the file folder and convert them to pdf.
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=strFolder & strFile)
 
    objDoc.ExportAsFixedFormat _
      OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
      ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False, OptimizeFor:=wdExportOptimizeForPrint, _
      Range:=wdExportAllDocument, Item:=wdExportDocumentContent
 
    objDoc.Close
    strFile = Dir()
  Wend
End Sub

4. Nunca se esqueça de clicar no botão “Executar”.

Observação: Em códigos “strFolder = “C:\Usuários\Teste\Desktop\Arquivos de Teste\”", a "“C:\Usuários\Teste\Desktop\Arquivos de Teste\”” é o caminho do arquivo da pasta. Lembre-se de alterá-lo de acordo.

Após executar esta macro, os PDFs serão salvos na mesma pasta onde os documentos do Word estão armazenados.

Arquivos seguros como você pode

Existem medidas preventivas e também ações pós-desastre para recuperar arquivos danificados. Se você fizer backups regulares dos seus arquivos, recuperar o arquivo original será muito fácil. A verdade é que poucas pessoas conseguem manter seus planos de backup, aumentando assim o risco de perda de dados valiosos. Nessas circunstâncias, é hora de recorrer a um método avançado de backup. Ferramenta de correção de corrupção de documento do Word.

Introdução do autor:

Vera Chen é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo reparo do Excel xlsx danificado e pdf reparar produtos de software. Para mais informações visite www.datanumen.com