2 métodos para enviar rapidamente células selecionadas em uma planilha do Excel como um e-mail do Outlook

Às vezes, você pode querer inserir rapidamente as células selecionadas em uma planilha do Excel em um e-mail do Outlook e enviar este e-mail. Este artigo examinará esse desejo para oferecer a você 2 métodos.

Meu artigo anterior “2 métodos rápidos para enviar uma planilha do Excel como um e-mail do Outlook” ensinou como enviar uma planilha inteira do Excel como um e-mail. No entanto, às vezes, você deseja apenas enviar as células selecionadas em uma planilha como um e-mail. Em resposta a esse requisito, apresentaremos aqui 2 métodos. Você pode escolher de acordo com sua preferência.

Método 1: Copiar células selecionadas para e-mail manualmente

1. Para começar, abra o arquivo Excel de origem e acesse a planilha correta.
2. Em seguida, selecione as células que deseja enviar como um e-mail do Outlook.
3. Em seguida, pressione os atalhos de tecla “Ctrl + C” para copiar as células selecionadas.
4. Depois disso, inicie seu aplicativo Outlook.
5. Posteriormente, clique no botão “Novo e-mail” na faixa “Página inicial” para criar um novo e-mail do Outlook.
6. Mais tarde, na nova janela Mensagem, clique na seção do corpo da mensagem.
7. Em seguida, pressione os botões das teclas “Ctrl + V” para colar as células selecionadas do Excel copiadas anteriormente.
8. Por fim, você pode redigir o e-mail como de costume e clicar no botão "Enviar" para enviá-lo.

Método 2: Enviar células selecionadas como e-mail via VBA

1. Logo no início, abra a pasta de trabalho de origem do Excel.
2. Em seguida, pressione os botões de tecla “Alt + F11” para acessar o editor Excel VBA.
3. Na nova janela, clique em “Inserir” > “Módulo” para inserir um novo módulo.
4. Em seguida, habilite a Biblioteca de Objetos do Microsoft Outlook. Clique em “Ferramentas” > “Referências”. Na caixa de diálogo que aparecer, localize e marque a opção “Biblioteca de Objetos do Microsoft Outlook”.
5. Posteriormente, copie o seguinte código VBA para este módulo.

Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

6. Eventualmente, você pode tentar.

• Em primeiro lugar, selecione as células específicas como de costume.
• Em seguida, volte para a nova macro e pressione a tecla F5 para acioná-la.
• Imediatamente, um novo e-mail do Outlook será exibido, no qual você pode ver que as células selecionadas foram inseridas no corpo do e-mail, conforme a captura de tela a seguir:

O arquivo PST é o mesmo vulnerável que o arquivo do Excel

Como sabemos, arquivos do Excel e documentos do Word são propensos à corrupção. Na verdade, o mesmo se aplica aos arquivos PST, que contêm todos os itens da sua caixa de correio do Outlook. Portanto, proteger os dados do seu arquivo PST é uma tarefa árdua. Uma das medidas mais eficazes é fazer backups regulares do arquivo. Além disso, para garantir uma recuperação imediata, é recomendável ter uma ferramenta confiável, como o [nome da ferramenta/serviço]. DataNumen Outlook Repair, que é capaz de recuperar Outlook dados sem suar a camisa.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo consertar mdf e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com