Hvordan raskt kopiere mappestruktur fra en Outlook PST-fil til en annen via VBA

Outlook-løsninger September 29, 2025

Hvis du vil kopiere mappestrukturen fra en Outlook PST-fil til en annen, kan du bruke metoden introdusert i denne artikkelen, som vil lære deg hvordan du bruker VBA for å få den på én gang.

For å bedre administrere e-postene dine har du kanskje opprettet flere egendefinerte mapper i Outlook-hovedfilen din. Når du oppretter en ny Outlook PST-fil, vil du kanskje bruke samme mappestruktur. Faktisk, i min forrige artikkel - "2 trinn for å beholde gjeldende mappe Hierarchy i en ny Outlook-fil", kan du lære en tradisjonell metode, som bruker "Arkiv"-funksjonen for å oppnå det. Likevel er det faktisk fortsatt litt kjedelig. Sammenlignet med det vil det være mye raskere å bruke VBA-koder for å få det. Derfor vil vi i det følgende fortelle deg de forseggjorte trinnene og kodene.

Kopier mappestruktur raskt fra en Outlook PST-fil til en annen

Kopier mappestruktur fra en Outlook PST-fil til en annen

  1. Helt i begynnelsen, start Outlook-programmet ditt.
  2. Deretter trykker du på "Alt + F11" i Outlook-vinduet.
  3. Deretter går du inn i Outlook VBA-redigeringsvinduet.
  4. Deretter kopierer og limer du inn følgende VBA-koder i en ny modul.
Public objNewPSTFolder As Outlook.Folder
 
Sub CopyFolderStructure()
    Dim objFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
 
    'Get the folders of the source Outlook PST file
    Set objFolders = Outlook.Application.Session.Folders("Personal").Folders
 
    'Create the new pst file in your desired local folder and name
    Outlook.Application.Session.AddStore "E:\New PST File.pst"
    Set objNewPSTFolder = Session.Folders.GetLast()
 
    For Each objFolder In objFolders
        CreateFolder objFolder
    Next
 
    MsgBox "Completed!", vbOKOnly + vbInformation, "Copy Folder Structure"
End Sub
 
Sub CreateFolder(objFolder As Outlook.Folder)
    Dim objSubFolder As Outlook.Folder
 
    'Only copy the mail folder
    If (objFolder.DefaultItemType = olMailItem) Then
       'New Outlook PST file auto includes the "Deleted Items" folder, so skip it
       'Skip the useless mail folders - "Conversation Action Settings" and "Quick Step Settings"
       If (objFolder.Name <> "Deleted Items") And (objFolder.Name <> "Conversation Action Settings") And (objFolder.Name <> "Quick Step Settings") Then
 
          'Create the new folder
          objNewPSTFolder.Folders.Add objFolder.Name
          Set objNewPSTFolder = objNewPSTFolder.Folders.Item(objFolder.Name)
 
          For Each objSubFolder In objFolder.Folders
              CreateFolder objSubFolder
          Next
 
          Set objNewPSTFolder = objNewPSTFolder.parent
       End If
    End If

End Sub

VBA-koder - Kopier mappestruktur fra en Outlook PST-fil til en annen

  1. Deretter endrer du makrosikkerhetsnivået til lavt.
  2. Senere tilbake til VBA-redigeringsvinduet og trykk på "F5"-tasten for å kjøre makroen.
  3. Til slutt, etter at makroen er ferdig med å virke, vil du få en melding som ber "Fullført!".Melding som ber om Fullført
  4. På dette tidspunktet kan du gå til postnavigasjonsruten. Du vil se en ny Outlook-datafil som er i samme mappestruktur som kilde-PST-filen, som bildet nedenfor:Kopier mappestruktur

Takle nedslående PST-problemer

Siden Outlook PST er utsatt for feil, må mange av dere noen gang ha støtt på forskjellige problemer i Outlook. Overfor dem kan du først bruke Outlook-innboksreparasjonsverktøyet for å prøve. Hvis det mislykkes, kan du bruke et mer potent tredjepartsverktøy, for eksempel DataNumen Outlook Repair, som kan fikse Outlook PST-feil som en lek.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert SQL Server fastsette og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med

Kommentarer er stengt.