Snel de details van alle leden in een Outlook-contactgroep exporteren naar Excel

Standaard kunt u alleen de ledennamen en e-mailadressen in een contactgroep zien. Als u de andere gegevens van de leden wilt weten, kunt u de manier gebruiken die in dit artikel is geïntroduceerd.

Als u dubbelklikt op een contactgroep om deze te openen, kunt u in het bijbehorende venster alleen de namen en e-mailadressen van de groepsleden zien. U kunt de andere details van leden, zoals bedrijf, functie, telefoonnummer of zakelijk adres, enz. Niet achterhalen. In het algemeen moet u om deze details te verkrijgen de contacten die met de leden corresponderen, handmatig in uw map Contacten vinden. Het is te lastig. Hier laten we u een stukje VBA-code zien, waarmee u deze details snel naar een Excel-werkmap kunt exporteren.

Exporteer de details van alle leden in een contactgroep naar Excel

1. Begin met het openen van de Outlook-applicatie.
2. Vervolgens moet u op de sneltoetscombinaties "Alt + F11" drukken in het hoofdvenster van Outlook.
3. Vervolgens moet u in het nieuwe venster “Microsoft Visual Basic for Applications” een niet in gebruik zijnde module openen of direct een nieuwe module invoegen.
4. Kopieer en plak vervolgens de volgende VBA-code in deze module.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. Daarna kunt u voor een gemakkelijke controle het nieuwe VBA-project toevoegen aan de werkbalk Snelle toegang of het lint.
6. Stel later uw Outlook-macrobeveiligingsniveau in op laag.
7. Uiteindelijk kun je het proberen.

• Selecteer eerst een contactgroep.
• Druk vervolgens op de macroknop in de werkbalk Snelle toegang of op het lint.
• De macro wordt onmiddellijk uitgevoerd.
• Als het klaar is, krijg je de prompt "Voltooid!"
• Daarna kunt u naar de voorgedefinieerde lokale bestemmingsmap gaan, waarin u een nieuw Excel-bestand kunt vinden.
• Open het, je ziet de contactgegevens van de groepsleden, zoals de volgende schermafbeelding:

Raak niet in paniek bij problemen met Outlook

Niemand is bereid om Outlook-problemen te accepteren, ongeacht de pop-upfoutmelding of corrupte Outlook data bestand. Daarom zullen gebruikers de neiging hebben in paniek te raken wanneer ze Outlook-problemen tegenkomen. Als u in dat geval rustig wilt blijven, moet u twee benodigdheden bij de hand hebben. Een daarvan is de huidige Outlook-gegevensback-ups. De andere is krachtige Outlook-fix-software, zoals DataNumen Outlook Repair.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder sql herstel en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com