Snel een Outlook-regel maken om de afzenders van meerdere e-mails te blokkeren

Als u een regel wilt maken om de afzenders van meerdere geselecteerde e-mails te blokkeren, moet u meestal eerst de afzenders opschrijven en vervolgens handmatig een regel maken. Het is behoorlijk lastig. Daarom zullen we hier een veel snellere methode delen om deze met één klik te verkrijgen.

Sommige gebruikers denken dat de ingebouwde “ant-spam”-functie in Outlook niet zo effectief is als ze hopen. Daarom zijn ze gewend Outlook-regels te maken om de afzenders te blokkeren. In het volgende zullen we een snelle methode introduceren om een ​​regel te maken om de afzenders van meerdere e-mails te blokkeren.

Maak snel een regel om afzenders van meerdere e-mails te blokkeren

1. Start om te beginnen de Outlook-applicatie.
2. Open vervolgens het VBA-editorvenster via de sneltoets "Alt + F11".
3. Plaats vervolgens in het nieuwe venster de volgende VBA-code in een ongebruikte module.

Sub CreateRuleForBlockingMultipleSenders()
    Dim objRules As Outlook.Rules
    Dim objRule As Outlook.Rule
    Dim objMoveRuleAction As Outlook.MoveOrCopyRuleAction
    Dim objFromCondition As Outlook.ToOrFromRuleCondition
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim objJunkFolder As Outlook.Folder
 
    Set objRules = Application.Session.DefaultStore.GetRules()
    'Create a rule
    Set objRule = objRules.Create("Block Senders", olRuleReceive)
    Set objFromCondition = objRule.Conditions.From
 
    'Get the selected emails
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    'Get Junk Email folder
    Set objJunkFolder = Outlook.Application.Session.GetDefaultFolder(olFolderJunk)
 
    For i = objSelection.Count To 1 Step -1
        If objSelection.Item(i).Class = olMail Then
 
           Set objMail = objSelection.Item(i)
 
           'Add the email senders to rule condition
           With objFromCondition
                .Enabled = True
                .Recipients.Add objMail.SenderEmailAddress
                .Recipients.ResolveAll
           End With
 
           'Move the emails from blocked senders to Junk Email folder
           Set objMoveRuleAction = objRule.Actions.MoveToFolder
           With objMoveRuleAction
                .Enabled = True
                .Folder = objJunkFolder
           End With
         End If
    Next
 
    objRules.Save
End Sub

4. Daarna, in overeenstemming met “Hoe u VBA-code in uw Outlook uitvoert“, voeg deze macro toe aan de werkbalk Snelle toegang of het lint.
5. Sluit vervolgens de VBA-editor normaal af.
6. Voer ten slotte de volgende stappen uit om het te proberen.

• Selecteer eerst de e-mails waarvan u de afzenders wilt blokkeren.
• Klik vervolgens op de nieuwe macroknop.
• Nadat de macro is voltooid, kunt u naar het menu "Bestand" gaan en op de knop "Regels en waarschuwingen beheren" klikken om de nieuw toegevoegde regel te controleren, zoals weergegeven in de onderstaande afbeelding.

Houd schadelijke e-mails op afstand

Ongeacht welke e-mailclient u gebruikt, ontvangt u waarschijnlijk regelmatig e-mails van onbekende afzenders. De meeste van deze e-mails zijn reclamespam en bevatten zelfs schadelijke macro's. Deze kunnen uw Outlook-bestand in een oogwenk beschadigen. Daarom is het belangrijk om in Outlook effectieve maatregelen te nemen om onbekende e-mails te blokkeren. Daarnaast is het, indien mogelijk, raadzaam om een ​​krachtige PST-hersteltool te gebruiken, zoals... DataNumen Outlook Repair. Het kan reparatie Outlook bestand zonder moeite, hoe ernstig het ook beschadigd is.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder sql herstel en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com