Hoe u alle hyperlinks in batch opent met een specifiek domein in uw Outlook-e-mail

Wanneer u een Outlook-e-mail bekijkt die veel hyperlinks in de hoofdtekst bevat, wilt u soms alleen de hyperlinks met een specifiek domein snel openen. Hier zullen we een methode delen om dergelijke hyperlinks in bulk te openen.

In het geval van meerdere hyperlinks in één e-mail, hoopt u misschien enkele ervan te bekijken, in plaats van alle. U wilt bijvoorbeeld alleen de hyperlinks in batch openen met een specifiek domein. Over het algemeen moet u één voor één klikken om ze te openen. Het is erg lastig. Daarom leren we u in het volgende een gemakkelijkere manier.

Batch Open alle hyperlinks met een specifiek domein in e-mail

1. Voor alstart, open de Outlook VBA-editor volgens “Hoe u VBA-code in uw Outlook uitvoert'.
2. Schakel vervolgens in het venster "Microsoft Visual Basic for Applications" de verwijzing naar "MS Word Object Library "met verwijzing naar"Hoe u een object kunt toevoegen Library Referentie in VBA'.
3. Kopieer vervolgens de volgende VBA-code naar een ongebruikte module of project.

Sub BatchOpenHyperlinksWithSpecificDomain()
    Dim objMail As MailItem
    Dim objMailDocument As Word.Document
    Dim objHyperlink As Word.Hyperlink
    Dim objDictionary As Object
    Dim i As Integer
    Dim varHyperlinks As Variant
    Dim varHyperlink As Variant
    Dim objInternetExplorer As Object
 
    'Get the source email
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
    Set objMailDocument = objMail.GetInspector.WordEditor
    For Each objHyperlink In objMailDocument.Hyperlinks
        If InStr(1, objHyperlink.Address, "www.datanumen.com") > 0 Then
           'Add Hyperlinks to Dictionary
           If objDictionary.Exists(objHyperlink.Address) = False Then
              objDictionary.Add objHyperlink.Address, 1
           End If
        End If
    Next
 
    'Batch Open Hyperlinks on different tabs in same Internet Explorer window
    Set objInternetExplorer = CreateObject("InternetExplorer.Application")
    varHyperlinks = objDictionary.Keys
    For i = LBound(varHyperlinks) To UBound(varHyperlinks)
        varHyperlink = varHyperlinks(i)
 
        If i = 0 Then
           objInternetExplorer.Visible = True
           objInternetExplorer.navigate varHyperlink
        Else
           objInternetExplorer.navigate varHyperlink, CLng(2048)
        End If
    Next
End Sub

4. Voeg vervolgens deze macro toe aan de werkbalk Snelle toegang of het lint.
5. Voer tot slot de volgende stappen uit om het te proberen.

• Selecteer of open eerst een Outlook-e-mail.
• Klik vervolgens op de macroknop.
• De hyperlinks met het vooraf gedefinieerde domein in de e-mail worden meteen in een batch geopend in Internet Explorer, zoals weergegeven in de volgende afbeelding:

Weg met irritante Outlook-corruptie

Hoewel Outlook vatbaar is voor fouten en corruptie, kunt u er in feite gemakkelijk aan ontsnappen, zolang u op alle risico's let. U moet bijvoorbeeld regelmatig gegevensback-ups maken voor Outlook. Bovendien moet u opletten voor de verdachte e-mails die mogelijk virussen bevatten. Last but not least kun je beter een Outlook-reparatie hulpprogramma, zoals DataNumen Outlook Repair. Het kan u helpen in het geval van Outlook-corruptie.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder corrupt SQL Server en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com