Batch Meerdere concept-e-mails opslaan als Outlook-sjablonen

Misschien heb je verschillende concept-e-mails gemaakt en hoop je ze opnieuw te gebruiken vele keren. Zo ja, waarom slaat u ze dan niet in batch op als Outlook-sjablonen? In dit artikel leer je hoe je dit in één keer kunt doen via VBA.

Standaard staat Outlook gebruikers alleen toe om één e-mail in één keer als sjabloon op te slaan. Met andere woorden, u kunt niet meerdere concept-e-mails in bulk opslaan als sjablonen. Zoals u kunt zien, wanneer u meer dan één mail selecteert en naar "Bestand"> "Opslaan als" gaat, kunt u de indeling "Outlook-sjabloon" niet vinden in de lijst "Opslaan als type", alleen "Alleen tekst" beschikbaar. Maar we zullen u in het volgende laten zien hoe u dit in bulk kunt realiseren.

Batch Bewaar meerdere concept-e-mails als Outlook-sjablonen

1. Activeer vanaf het begin de Outlook VBA-editor.
2. Kopieer en plak de onderstaande VBA-code in het nieuwe venster "Microsoft Visual Basic for Applications".

Sub SaveMultipleDraftsAsTemplates()
    Dim objSelection As Outlook.Selection
    Dim i As Long
    Dim strTemplateFolder As String
    Dim objMail As Outlook.MailItem
    Dim strSubject As String
 
    'Get all selected mails
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
       'Get the default folder for saving Outlook Templates
       strTemplateFolder = CStr(Environ("USERPROFILE")) & "\Documents\UserTemplates\"
 
       'Save each mail as template
       For i = objSelection.Count To 1 Step -1
           If objSelection(i).Class = olMail Then
              Set objMail = objSelection(i)
              If objMail.Subject <> "" Then
 
                 'Remove unsupported characters
                 strSubject = objMail.Subject
                 strSubject = Replace(strSubject, "/", " ")
                 strSubject = Replace(strSubject, "\", " ")
                 strSubject = Replace(strSubject, ":", "")
                 strSubject = Replace(strSubject, "?", " ")
                 strSubject = Replace(strSubject, Chr(34), " ")
 
                 objMail.SaveAs strTemplateFolder & strSubject & ".oft", olTemplate
              Else
                 objMail.SaveAs strTemplateFolder & "Template" & i & ".oft", olTemplate
              End If
           End If
       Next
 
       'Open the folder of Templates
       Shell "Explorer.exe" & " " & strTemplateFolder, vbNormalFocus
    End If
End Sub

3. Daarna wordt, voor later gemak, voorgesteld om deze macro toe te voegen aan de Quick Access Toolbar (QAT). Over gedetailleerde stappen kunt u lezen "Hoe u VBA-code in uw Outlook uitvoert"
4. Uiteindelijk kunt u een foto maken door de onderstaande bewerkingen te volgen.

• Selecteer eerst de concept-e-mails die u als sjablonen wilt opslaan.
• Klik vervolgens op de macroknop in de QAT.
• Wanneer de macro is voltooid, wordt de Windows-map voor het opslaan van de standaard Outlook-sjablonen weergegeven. U kunt zien dat de sjablonen van de geselecteerde concept-e-mails daar staan.

Inbox-reparatietool kan nog steeds mislukken

Als het gaat om de interne Outlook-fixtool - Scanpst, zullen een groot aantal gebruikers het op prijs stellen. Dit hulpprogramma is ongetwijfeld in staat om de meeste kleine problemen in Outlook op te lossen. Toch is het niet helemaal onberispelijk. Het kan nog steeds mislukken en veel fouten opleveren. Bijvoorbeeld in het geval van ernstige Outlook corruptie, is het niet in staat om het gecompromitteerde PST-bestand te repareren. In dat scenario heb je geen alternatief, maar moet je een machtiger en tip-top hulpmiddel van derden gebruiken, zoals DataNumen Outlook Repair.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder sql herstel en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com