Batchen Verwijder alle e-mailadressen met een specifiek domein uit uw Outlook-contactpersonen

Soms wil je misschien alle e-mailadressen met een specifiek domein uit je contacten verwijderen. In dat geval wil je dat waarschijnlijk niet één voor één doen. Daarom laten we je in dit artikel een veel slimmere methode zien.

Een bedrijf verandert bijvoorbeeld zijn naam. Ondertussen wordt ook het bedrijfsdomein gewijzigd. In Outlook hebt u echter veel contacten in dit bedrijf opgeslagen, waarvan de e-mailadressen in het oude domein zijn. Deze e-mailadressen zijn natuurlijk niet meer geldig. Als u onder deze omstandigheden deze e-mailadressen in één keer wilt verwijderen, kunt u de volgende manier gebruiken.

Batch Verwijder alle e-mailadressen met een specifiek domein uit Contacten

1. Om te beginnen kunt u de VBA-editor van Outlook openen met de sneltoets "Alt + F11".
2. Plaats vervolgens in het nieuwe venster de volgende VBA-code in een lege module.

Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

3. Plaats daarna de cursor in de subroutine "BatchRemoveAllEmailAddressesInSpecificDomain".
4. Klik ten slotte op de toets "F5" om deze macro te activeren.
5. Voer vervolgens het specifieke domein in het pop-upvenster in.
6. Nadat u op "OK" hebt geklikt, wordt de macro uitgevoerd.
7. Als het klaar is, krijgt u een bericht over de resultaten.
8. Nu kunt u de contacten controleren. Alle e-mailadressen met het specifieke domein moeten zijn verdwenen.

Bewaar uw Outlook-bestand

Met steeds meer risico's rondom uw Outlook, wordt het steeds moeilijker om uw waardevolle Outlook-gegevens te beschermen. U moet bijvoorbeeld niet alleen volharden in regelmatige gegevensback-ups, maar u moet ook op uw activiteiten letten. Het is niet verstandig om gemakkelijk te vertrouwen op e-mails van onbekende afzenders. Anders, als het virus bevat, wordt uw Outlook-bestand geïnfecteerd. Op dat moment moet je het proberen Outlook-reparatie via een opmerkelijke fix-tool, zoals DataNumen Outlook Repair.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder herstellen Sql Server en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com