Hoe u in batch alle leesbevestigingen in uw Outlook kunt verwijderen

Om te bevestigen dat de ontvangers je e-mail hebben gelezen, kun je bij het opstellen van de e-mail een leesbevestiging aanvragen. In dat geval kan je mailbox vol raken met dergelijke leesbevestigingen. In dit artikel leer je hoe je deze in één keer permanent kunt verwijderen.

Na het lezen van het artikel “Hoe u batchgewijs alle ontvangstbewijzen in uw Outlook kunt verwijderen“, Denkt u misschien aan de aanpak om alle leesbevestigingen in bulk te verwijderen. In feite is het duidelijke verschil tussen de twee soorten ontvangsten hun onderwerp. De ontvangstbevestiging bevat 'Bezorgd' als onderwerp, maar de leesbevestiging bevat in plaats daarvan 'Gelezen'. Daarom kunt u op dezelfde manier alle leesbevestigingen in batch verwijderen. Hieronder leren wij u de concrete stappen in detail.

Batch verwijder alle leesbevestigingen

1. Start allereerst Outlook op.
2. Ga vervolgens naar de Outlook VBA-editor via "Alt + F11" volgens "Hoe u VBA-code in uw Outlook uitvoert'.
3. Open vervolgens in het nieuwe venster een lege module en plaats de volgende code erin.

Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

4. Klik daarna op de eerste subroutine.
5. Druk ten slotte op de toets "F5".
6. In één keer zal de macro werken om alle leesbevestigingen uit uw Outlook te verwijderen.
7. Wanneer het klaar is, krijgt u een melding over het resultaat, zoals in de onderstaande schermafbeelding.
8. Momenteel kunt u uw e-mailmappen controleren. Alle leesbevestigingen zijn verdwenen.

Verdedig Outlook-gegevens

Hoewel het Outlook-bestand weliswaar vatbaar is voor corruptie, kunnen we actie ondernemen om het te beschermen. We moeten het Outlook-bestand bijvoorbeeld klein houden, het beschermen tegen kwaadwillende factoren en er regelmatig een back-up van maken. Last but not least kunt u beter een krachtige externe PST-reparatietool voorbereiden, zoals DataNumen Outlook Repair. Het zal grote gevolgen hebben voor de reparatie corrupte Outlook bestand.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder sql reparatie en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com