Hoe automatisch verschillende herinneringstijd instellen voor Outlook-vergaderingen in verschillende kleurcategorieën

Outlook-oplossingen 29 september 2025

Als u Outlook-vergaderingen classificeert op kleurcategorieën en verschillende herinneringstijd wilt instellen voor vergaderingen in verschillende kleurcategorieën, kunt u dit artikel raadplegen. Hier leren we je om het te realiseren met Outlook VBA.

Stel, u verdeelt uw vergaderingen in twee groepen. De ene groep valt onder de categorie 'Extern' omdat de vergaderlocatie te ver weg is, en de andere onder de categorie 'Op locatie' omdat de locatie zich op dezelfde plek bevindt. U wilt nu dat Outlook de herinneringstijd voor vergaderingen op afstand automatisch instelt op 1 uur voor aanvang en voor vergaderingen op locatie op 15 minuten voor aanvang. Hieronder vindt u een snelle methode om dit te realiseren.

Stel automatisch verschillende herinneringstijd in voor Outlook-vergaderingen in verschillende kleurcategorieën

Automatisch verschillende herinneringen instellen voor vergaderingen in verschillende kleurcategorieën

  1. Start om te beginnen uw Outlook-applicatie.
  2. Druk vervolgens op de toetsen "Alt + F11" om toegang te krijgen tot het VBA-editorvenster.
  3. Kopieer en plak vervolgens in het volgende venster de onderstaande VBA-code in het project "ThisOutlookSession".
Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

VBA-code - Automatisch verschillende herinneringen instellen voor vergaderingen in verschillende kleurcategorieën

  1. Later moet je in de subroutine "Application_Startup" klikken en op de F5-toets drukken om deze macro uit te voeren.
  2. Sindsdien zal Outlook elke keer dat een nieuwe vergadering wordt toegevoegd aan de standaardagenda of een bestaande vergadering wijzigt, automatisch de categorieën van de vergadering controleren en automatisch de verschillende herinneringstijd instellen.Verschillende herinneringstijd voor vergaderingen in verschillende kleurcategorieën

Elimineer Outlook-fouten

Er kunnen zich van tijd tot tijd diverse problemen voordoen met Outlook. Daarom is het uiterst belangrijk dat gebruikers leren hoe ze met Outlook-problemen om moeten gaan. Om te beginnen is het raadzaam om regelmatig een back-up van uw Outlook-gegevens te maken. Bovendien is het, indien mogelijk, aan te raden om een ​​krachtige back-up te bewaren. Outlook-reparatie tool in de buurt, zoals DataNumen Outlook Repair. Het kan uw PST-bestand scannen om Outlook-problemen op te lossen en deze vervolgens gemakkelijk op te lossen.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder sql herstel en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com

Reacties zijn gesloten.