3 manieren om statistieken over het aantal woorden te krijgen met betrekking tot tekstvakken, voetnoten en eindnoten in uw document

In het artikel van vandaag zijn er drie snelle manieren om statistieken over het aantal woorden te krijgen met betrekking tot tekstvakken, voetnoten en eindnoten in uw document.

Het is niet moeilijk om het totale aantal woorden in een document te krijgen. Maar als u het aantal woorden van verschillende soorten teksten wilt hebben, zijn er meer bewerkingen nodig. Hieronder volgen drie methoden. Lees verder om te zien wat u kunt gebruiken. 

Methode 1: tel woorden inclusief teksten uit tekstvakken, voetnoten en eindnoten

Standaard telt Word alle woorden die in het document verschijnen, inclusief teksten in tekstvakken en ook woorden uit voetnoten en eindnoten.

1. Ga allereerst naar de statusbalk en klik op 'Woorden' om het venster 'Woordentelling' te openen.
2. Daar zie je allerlei statistieken. Zorg ervoor dat u het vakje “Inclusief tekstvakken, voetnoten en eindnoten” heeft aangevinkt.
3. Klik vervolgens op "Sluiten".
4. Als u het "Words" -commando op de statusbalk niet kunt vinden, klikt u daar met de rechtermuisknop op.
5. Controleer vervolgens de “Word Count”.

Methode 2: sluit teksten uit tekstvakken, voetnoten en eindnoten uit van het aantal woorden

Dit is het tegenovergestelde van methode 1. U hoeft dus alleen het vakje "Inclusief tekstvakken, voetnoten en eindnoten" uit te schakelen.

Methode 3: Voer Word Macro uit om een ​​afzonderlijke telling van woorden uit tekstvakken, voetnoten en eindnoten te krijgen

1. Activeer eerst het vak "Aantal woorden" op de manier in methode 1 en zorg ervoor dat het keuzevakje is aangevinkt.
2. Druk vervolgens op "Alt + F11" om de VBA-editor te openen.
3. Voeg vervolgens een nieuwe module in het “Normaal” project in door eerst op “Normaal” te klikken.
4. En klik vervolgens op "Invoegen".
5. Kies dan "Module".
6. Dubbelklik op de module om het coderingsgedeelte te openen en plak de volgende codes daar:

Sub SeparateCountNumberOfTextboxFootnoteEndnote()
  Dim lTextboxWords As Long
  Dim lTextboxChars As Long
  Dim lDocumntWords As Long
  Dim lDocumntChars As Long
  Dim objTextboxShape As Shape
  Dim objTemp As Dialog
  Dim bDone As Boolean
  Dim objRange As Range
  Dim lFootnoteWords As Long
  Dim lFootnoteChars As Long
  Dim lEndnoteWords As Long
  Dim lEndnoteChars As Long
 
  Application.ScreenUpdating = False

 Do
   bDone = True
   For Each objTextboxShape In ActiveDocument.Shapes
     If objTextboxShape.Type = msoGroup Then
       objTextboxShape.Ungroup
       bDone = False
     End If
   Next objTextboxShape
 Loop Until bDone

 '  Count the words and characters in the whole document.
 Selection.HomeKey Unit:=wdStory
 Set objTemp = Dialogs(wdDialogToolsWordCount)
   objTemp.Update
   objTemp.Execute
   lDocumntWords = objTemp.Words
   lDocumntChars = objTemp.Characters
 
 With ActiveDocument
 '  Count the words and characters in all textboxes.
   lTextboxWords = 0
   lTextboxChars = 0
   If ActiveDocument.Shapes.Count > 0 Then
     For Each objTextboxShape In .Shapes
       objTextboxShape.Select
       objTemp.Execute
       lTextboxWords = lTextboxWords + objTemp.Words
       lTextboxChars = lTextboxChars + objTemp.Characters
     Next objTextboxShape
   Else
     MsgBox ("There is no text box in this document")
   End If

   '  Count the words and characters in all footnotes.
   lFootnoteWords = 0
   lFootnoteChars = 0
   If ActiveDocument.Footnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdFootnotesStory Then
         objRange.Select
         objTemp.Execute
         lFootnoteWords = lFootnoteWords + objTemp.Words
         lFootnoteChars = lFootnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no footnote in this document")
   End If

   '  Count the words and characters in all endnotes. 
   lEndnoteWords = 0
   lEndnoteChars = 0
   If ActiveDocument.Endnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdEndnotesStory Then
         objRange.Select
         objTemp.Execute
         lEndnoteWords = lEndnoteWords + objTemp.Words
         lEndnoteChars = lEndnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no Endnote in this document")
   End If
 End With
 
 Application.ScreenUpdating = True

 MsgBox (" In this document there are totally" & vbCr _
   & Str(lDocumntWords) & " word(s) and" & Str(lDocumntChars) & " characters" & vbCr & vbCr _
   & "Including:" & vbCr _
   & Str(ActiveDocument.Shapes.Count) & " textboxes contain(s)" & vbCr _
   & Str(lTextboxWords) & " word(s)," & Str(lTextboxChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Footnotes.Count) & " footnotes contain(s)" & vbCr _
   & Str(lFootnoteWords) & " word(s)," & Str(lFootnoteChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Endnotes.Count) & " Endnotes contain(s)" & vbCr _
   & Str(lEndnoteWords) & " word(s)," & Str(lEndnoteChars) & " characters")
End Sub

7. Klik ten slotte op de knop "Uitvoeren".

Als er geen tekstvak, voetnoot of eindnoot is, ontvangt u een berichtvenster als volgt:

Klik gewoon op "OK" om door te gaan. Dan zul je een ander vak zien met alle details van het aantal woorden.

Download een hersteltool

Omdat Word ineens kan instorten, is het raadzaam om een ​​geavanceerd reparatieproduct aan te schaffen om de reparatie uit te voeren. Zo'n tool kan een geweldige bespaarder zijn corrupt woord. Grijp daarom de tijd om er zo snel mogelijk een te kopen.

Auteur Introductie:

Vera Chen is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder xls repareren en pdf reparatie softwareproducten. Voor meer informatie bezoek www.datanumen.com