3 snelle manieren om lege rijen en kolommen in uw Word-tabel te verwijderen

In dit bericht leggen we je 3 snelle manieren uit om lege rijen en kolommen in je Word-tabel te verwijderen.

Tabellen zijn essentieel voor een document, vooral omdat het verschillende soorten gegevens bevat. Soms kan een lange tabel langer zijn dan een pagina en zich uitstrekken over meerdere. Dus als een tabel eenmaal lang en ingewikkeld wordt, zijn er maatregelen die u kunt nemen om deze te vereenvoudigen. U kunt bijvoorbeeld onnodige lege rijen en kolommen verwijderen.

Hieronder volgen drie methoden die u kunt gebruiken.

Methode 1: verwijder lege rijen en kolommen handmatig

1. Selecteer eerst een rij of kolom die leeg is.
2. Klik vervolgens met de rechtermuisknop om het contextmenu te openen. Selecteer in het menu "Rijen verwijderen" of "Kolommen verwijderen" overeenkomstig.

Helaas kunt u niet meerdere niet-opeenvolgende rijen of kolommen selecteren en ze op deze manier samen verwijderen. Voor deze vraag kunt u ons vorige artikel raadplegen: 5 snelle methoden om batchgewijs meerdere rijen of kolommen in uw Word-tabel te verwijderen

Methode 2: Batch Verwijder alle lege rijen en kolommen in een tabel

Methode 1 heeft zijn beperking. Daarom bieden we u de manier om batchgewijs rijen en kolommen in een tabel te verwijderen via VBA-codes.

1. Plaats om te beginnen de cursor in de gewenste tabel.
2. Ten tweede, activeer de VBA-editor door op "Alt + F11" te drukken.
3. Klik in de editor eerst op “Normaal” project.
4. Klik vervolgens op het tabblad "Invoegen" op de menubalk.
5. Kies "Module" in het vervolgkeuzemenu.
6. Dubbelklik op de module om deze te openen en plak daar de volgende codes:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Klik ten slotte op de knop "Uitvoeren" op de menubalk of druk op "F5".

Binnen enkele seconden zijn alle lege rijen en kolommen in die tabel verwijderd.

Methode 3: Batch Verwijder alle lege rijen en kolommen in alle tabellen in een document

1. Herhaal eerst de stappen in methode 2 om een ​​macro te installeren en uit te voeren.
2. Vervang deze keer alleen die macro door het volgende:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Herstel gebroken document

Er zijn tegenwoordig meer manieren om verloren gegevens terug te halen. Zo blijft het maken van back-ups altijd de beste optie. Als dat niet voldoende is om de meest recente informatie terug te krijgen, kunt u een andere methode proberen. doc reparatie en vermijd negatieve reviews.

Auteur Introductie:

Vera Chen is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder xlsx reparatie en pdf reparatie softwareproducten. Voor meer informatie bezoek www.datanumen.com