2 snelle manieren om de lijst met alle gemarkeerde Outlook-e-mails naar Excel te exporteren

Als u de lijst met alle gemarkeerde e-mails van uw Outlook-mailbox naar Excel wilt exporteren, kunt u een van de twee methoden gebruiken die in dit artikel worden gedeeld.

Als u bijvoorbeeld alle gemarkeerde e-mails sneller wilt afhandelen of ze met iemand anders wilt delen, kunt u hopen ze naar een Excel-werkblad te exporteren. Hier zullen we 2 benaderingen introduceren om dit te realiseren. De eerste gebruikt de standaard "Import en Export" -functie na het vinden van gemarkeerde e-mails. Om eerlijk te zijn, het is een beetje vervelend. Dus in de laatste zullen we je een gemakkelijkere manier leren om VBA toe te passen.

Exporteer de lijst met alle gemarkeerde Outlook-e-mails naar Excel

Methode 1: alle gevonden gemarkeerde e-mails handmatig exporteren

  1. Klik eerst in het zoekvak boven de mailinglijst.
  2. Klik vervolgens op "Alle poststukken" in de groep "Bereik" op het tabblad "Zoeken".
  3. Klik vervolgens op de knop "Gemarkeerd" in de groep "Definiëren".Zoek gemarkeerde e-mails
  4. Nadat alle gemarkeerde e-mails in de lijst zijn weergegeven, selecteert u één e-mail en drukt u op "Ctrl + A" om ze allemaal te selecteren.
  5. Druk vervolgens op de toetscombinaties "Ctrl + Shift + V".
  6. Maak in het nieuwe dialoogvenster een nieuwe map onder het Outlook-bestand.Maak een nieuwe folder
  7. Selecteer later de nieuw gemaakte map en klik op "OK", waardoor alle gevonden gemarkeerde e-mails naar de nieuwe map worden verplaatst.Verplaats alle gemarkeerde e-mails naar de nieuwe map
  8. Klik daarna op "Bestand"> "Openen"> "Importeren",
  9. Kies in het pop-upvenster "Exporteren naar een bestand"> "Volgende"> "Microsoft Excel 97-2003"> "Volgende".Naar een bestand exporteren
  10. Selecteer in het nieuwe scherm de juiste map en klik op "Volgende".Selecteer de map waaruit u wilt exporteren
  11. Volg daarna de wizards om "Exporteren" te voltooien.
  12. U krijgt een nieuw Excel-bestand, weergegeven als de volgende schermafbeelding.Geëxporteerd Excel-bestand

Methode 2: exporteer de lijst met alle gemarkeerde e-mails via VBA

  1. Druk in Outlook op "Alt + F11" om de VBA-editor te activeren.
  2. Schakel vervolgens "MS Excel Object" in in overeenstemming met "Hoe voeg je een verwijzing naar een objectbibliotheek toe in VBA?'.
  3. Kopieer vervolgens de onderstaande VBA-code naar een module.
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

VBA-code - Exporteer de lijst met alle gemarkeerde e-mails

  1. Plaats ten slotte de cursor in de "ExportAllFlaggedEmailsToExcel" subroutine en druk op de "F5" toets.
  2. Selecteer vervolgens een Outlook-bestand in het nieuwe dialoogvenster.Selecteer Outlook-bestand
  3. Wanneer u de prompt "Voltooid" krijgt, krijgt u ook een nieuw Excel-bestand, zoals de afbeelding hieronder.Geëxporteerd Excel-bestand via VBA

Bescherm uw Outlook tegen corruptie

Outlook is gevoelig voor fouten en corruptie, waardoor het een zeer lastige taak is om onze Outlook-gegevens te beschermen. De meest effectieve en praktische manier is ongetwijfeld om regelmatig back-ups van uw Outlook-gegevens te maken. Daarnaast is het ook noodzakelijk om een ​​krachtige en betrouwbare tool voor het herstellen van Outlook-problemen te gebruiken, zoals... DataNumen Outlook Repair. Het zal van pas komen als inbox reparatieprogramma heeft geen effect.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder repareren SQL Server en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com

Reacties zijn gesloten.