2 Methoden om batchgewijs alle contacten zonder e-mailadres in uw Outlook te verwijderen

Als je merkt dat sommige contactpersonen in je Outlook geen e-mailadres hebben, kun je de betreffende contactmappen doorlopen en al deze contactpersonen verwijderen. In dit artikel worden twee manieren beschreven om dit te doen.

Misschien heeft u veel contacten in uw Outlook en sommige hebben geen e-mailadres. Als u denkt dat ze niet langer bruikbaar zijn, moet u hopen alle contacten zonder e-mailadres te verwijderen. Op de standaardmanier kunt u "Direct zoeken" gebruiken om ze te vinden en ze vervolgens handmatig te verwijderen, zoals bij de volgende methode 1. Toch is het een beetje vervelend. Daarom zullen we u in Methode 2 een andere, efficiëntere manier leren.

Methode 1: handmatig verwijderen nadat u contactpersonen zonder e-mailadres hebt gevonden

1. Druk om te beginnen op de toetsen "Ctrl + 3" om het paneel "Contacten" te openen.
2. Klik vervolgens in het zoekvak.
3. Klik vervolgens in het nieuwe "Zoeken" -lint op "Alle contactitems".
4. Klik vervolgens op "Heeft adres"> "Heeft e-mailadres".
5. Daarna wordt het criterium "GEEN e-mailadressen: = []" toegevoegd aan het zoekvak. U moet de "NOT" verwijderen.
6. Vervolgens worden alle contacten zonder e-mailadres weergegeven.
7. Nu moet u contacten in de zoekresultaten handmatig selecteren, omdat uw contactgroepen ook in de lijst moeten staan.
8. Druk ten slotte op de toets "Del" om alle geselecteerde contacten te verwijderen.

Methode 2: Batch Verwijder alle contacten zonder e-mailadres met VBA

1. Tik eerst op "Alt + F11" om de VBA-editor in Outlook te starten.
2. Kopieer in het nieuwe scherm de volgende VBA-code naar een module.

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

3. Klik later op de subroutine "BatchDeleteAllContactsWithoutEmailAddress".
4. Druk uiteindelijk op "F5" om deze macro te activeren.
5. Als het voltooid is, krijgt u een bericht over de resultaten, zoals in de onderstaande afbeelding.
6. Alle contacten zonder e-mailadres zijn verplaatst naar de map "Verwijderde items".

Blijf ver weg van alle mogelijke risico's

Outlook kan beschadigd raken door verschillende factoren, zoals virussen, gebruikersfouten, softwarefouten en hardwarefouten. U moet onwillig zijn om Outlook-schade op te lopen, dus u moet al deze potentiële risico's op afstand houden. U moet bijvoorbeeld krachtige antivirussoftware op uw pc installeren. Bovendien moet u regelmatig een back-up van uw Outlook-gegevens maken. Last but not least kunt u beter een robuuste en betrouwbare reparatietool voorbereiden, zoals DataNumen Outlook Repair​ Het kan uw corrupte PST bestand met gemak.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder SQL Server corruptie en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com