အရောင်အမျိုးအစားတစ်ခုစီရှိ Outlook ချိန်းဆိုမှုများတွင် အသုံးပြုသည့် စုစုပေါင်းအချိန်ကို အမြန်ထုတ်ယူနည်း

အရောင်အမျိုးအစားတစ်ခုစီရှိ ချိန်းဆိုမှုများအတွက် သင်အသုံးပြုသည့် စုစုပေါင်းအချိန်နှင့်ပတ်သက်သည့် အစီရင်ခံစာတစ်ခုကို ဖန်တီးလိုပါက၊ ဤဆောင်းပါးတွင် ဖော်ပြထားသည့် နည်းလမ်းကို အသုံးပြုနိုင်သည်။ ကိုယ်တိုင်ရေတွက်ရန် မလိုအပ်ဘဲ ၎င်းကို အချိန်တိုအတွင်း ပြီးမြောက်အောင် ကူညီပေးနိုင်သည်။

အသုံးပြုသူအများစုဟာ သူတို့ရဲ့ လုပ်ဆောင်ချက်အများစုကို Outlook ပြက္ခဒိန်မှာ မှတ်တမ်းတင်လေ့ရှိပါတယ်။ ဒါ့အပြင်၊ ပိုမိုလွယ်ကူစွာ စီမံခန့်ခွဲနိုင်ဖို့နဲ့ ခွဲခြားနိုင်ဖို့အတွက် အမျိုးအစားတစ်ခုချင်းစီကို သတ်မှတ်ပေးလေ့ရှိပါတယ်။ ဒီကိစ္စမှာ အသုံးပြုသူတချို့က အရောင်အမျိုးအစားတစ်ခုချင်းစီမှာရှိတဲ့ ပြက္ခဒိန်ပစ္စည်းတွေအတွက် စုစုပေါင်းအချိန်ကုန်ဆုံးမှုကို ပြသတဲ့ အစီရင်ခံစာတစ်ခု ထုတ်ချင်ကြပါတယ်။ သေချာတာကတော့ ကိုယ်တိုင်ရေတွက်ပြီး ထည့်သွင်းဖို့ ခက်ခဲပါတယ်။ ဒါကြောင့် ရိုးရှင်းတဲ့ ကလစ်တစ်ချက်နှိပ်ရုံနဲ့ ဒီအလုပ်ကို ပြီးမြောက်အောင် လုပ်ဆောင်နိုင်တဲ့ နည်းလမ်းတစ်ခုကို မျှဝေပေးပါမယ်။

အရောင်အမျိုးအစားတစ်ခုစီရှိ ချိန်းဆိုမှုများတွင် သုံးစွဲသည့် စုစုပေါင်းအချိန်ကို ထုတ်ယူပါ။

1. ပထမဆုံးအနေနဲ့ သင့် Outlook အက်ပ်ကို စတင်လိုက်ပါ။
2. ထို့နောက် Outlook ဝင်းဒိုးသို့ ဝင်ရောက်ပြီးနောက်၊ သင်သည် “Alt + F11” ခလုတ်များကို နှိပ်နိုင်သည်။
3. ထို့နောက်တွင် သင်သည် “Microsoft Visual Basic for Applications” ဝင်းဒိုးသို့ ဝင်ရောက်ခွင့်ရရှိမည်ဖြစ်သည်။
4. နောက်တစ်ခုအနေနဲ့ “Microsoft Excel Object Library” ကို enable လုပ်ရပါမယ်။ ဒါကိုလုပ်ဖို့ “Tools” > “Reference” ကို နှိပ်နိုင်ပါတယ်။
5. ထို့နောက် အသုံးမပြုသော module တစ်ခုကို ရှာဖွေပြီး ဖွင့်သင့်သည်။
6. ထို့နောက်၊ သင်သည် အောက်ပါ VBA ကုဒ်ကို ဤ module ထဲသို့ ကူးယူရန် လိုအပ်သည်။

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. ကိရိယာဘားရှိ “Run” အိုင်ကွန်ကို နှိပ်ခြင်း သို့မဟုတ် “F5” ခလုတ်ခလုတ်ကို နှိပ်ခြင်းဖြင့် နောက်ဆုံးတွင် သင်သည် ဤမက်ခရိုကို အစပျိုးနိုင်သည်။
8. ထို့နောက် သတ်မှတ်ထားသော ပြက္ခဒိန်တစ်ခုကို ရွေးချယ်ရန် သင့်အား တောင်းဆိုလိမ့်မည်။
9. သင်ရွေးချယ်ပြီး “OK” ကိုနှိပ်ပြီးနောက်၊ မက်ခရိုသည် ဆက်လက်လည်ပတ်နေမည်ဖြစ်သည်။ ပြီးပါက၊ နောက်ခံတွင်ပြသသော Excel ဖိုင်အသစ်တစ်ခုပေါ်လာလိမ့်မည်။
10. သင်ဝင်ရောက်နိုင်သည်။ ၎င်းသည် အောက်ပါ screenshot နှင့်တူလိမ့်မည်-

သင့် Outlook ပတ်ဝန်းကျင်တွင် ဖြစ်နိုင်ချေရှိသော ခြိမ်းခြောက်မှုများကို စောင့်ကြည့်ပါ။

Outlook အသုံးပြုသူများသည် အမည်မသိ အီးမေးလ် ပူးတွဲပါဖိုင်များ၊ ထည့်သွင်းထားသော လင့်ခ်များနှင့် လူသားအမှားများ အပါအဝင် ဖြစ်နိုင်ချေရှိသော အန္တရာယ်အားလုံးကို သတိထားသင့်သည်။ မဟုတ်ပါက သင်၏ Outlook သည် အချိန်မရွေး ပျက်စီးသွားနိုင်သည်။ ထို့အပြင်၊ ပုံမှန် Outlook ဒေတာကို အရန်သိမ်းဆည်းခြင်းနှင့် အထူးပြုပြုပြင်ရေးကိရိယာတစ်ခုထားရှိခြင်းသည် မရှိမဖြစ်လိုအပ်ပါသည်။ DataNumen Outlook Repair အလွန်အကြံပြုထားသော ပြင်ဆင်ရေးကိရိယာများထဲမှ တစ်ခုဖြစ်သည်။ ၎င်းသည် Outlook ကိုပြုပြင်ပါ။ jiffy တွင်ပြဿနာများ။

စာရေးသူနိဒါန်း:

Shirley Zhang သည် ဒေတာပြန်လည်ရယူရေးဆိုင်ရာ ကျွမ်းကျင်သူဖြစ်သည်။ DataNumen, Inc. အပါအဝင် ဒေတာပြန်လည်ရယူရေးနည်းပညာများတွင် ကမ္ဘာ့ခေါင်းဆောင်ဖြစ်သည်။ ပျက်စီးနေသော mdf နှင့် outlook ပြုပြင်ရေး software ထုတ်ကုန်များ။ ပိုမိုသိရှိလိုပါကသွားရောက်ကြည့်ရှု www ။datanumen.com